dnl Process this file with autoconf to produce a configure script.

 dnl Version information.

 m4_define([glemon_version_major], [0])

 m4_define([glemon_version_minor], [5])

 m4_define([glemon_version_micro], [90])

 m4_define([glemon_version_nano], [])

 m4_define([glemon_version_tag], [hg_])

 m4_define([glemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])

 m4_define([glemon_version], [glemon_version_major().glemon_version_minor()ifelse(glemon_version_micro(), [], [], [.glemon_version_micro()])ifelse(glemon_version_nano(), [], [], [.glemon_version_nano()])ifelse(glemon_version_tag(), [], [], glemon_version_tag(), [hg_], [[_]glemon_version_tag()[]glemon_hg_revision()], [[_]glemon_version_tag()])])

 AC_PREREQ([2.59])

 AC_INIT([gLEMON], [glemon_version()], [etik-ol@cs.elte.hu], [glemon])

 AC_CONFIG_AUX_DIR([build-aux])

 AC_CONFIG_MACRO_DIR([m4])

 AM_INIT_AUTOMAKE([-Wall -Werror foreign])

 AC_CONFIG_SRCDIR([main_win.h])

 AC_CONFIG_HEADERS([config.h])

 dnl Checks for programs.

 AC_PROG_CXX

 AC_PROG_CC

 AM_GNU_GETTEXT_VERSION([0.17])

 AM_GNU_GETTEXT([external])

 dnl Checks for libraries.

 PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0 gtkmm-2.4 >= 2.6])

 AC_ARG_WITH([lemon],

 AS_HELP_STRING([--with-lemon@<:@=PREFIX@:>@], [search for LEMON under PREFIX]), [], [with_lemon=no])

 if test x"$with_lemon" != x"no"; then

   export PKG_CONFIG_PATH="$with_lemon/lib/pkgconfig/:$PKG_CONFIG_PATH"

 fi

 PKG_CHECK_MODULES([LEMON], [lemon >= 0.6.90], [], [AC_MSG_ERROR([

 No appropriate version of package 'lemon' found.

 Consider adjusting the PKG_CONFIG_PATH environment variable or using

 the --with-lemon=PREFIX configure flag if you installed it in a

 non-standard prefix.

 Alternatively, you may set the environment variables LEMON_CFLAGS and

 LEMON_LIBS to avoid the need to call pkg-config.  See the pkg-config

 man page for more details.])])

 dnl Checks for header files.

 AC_CHECK_HEADERS([libintl.h locale.h])

 dnl Checks for typedefs, structures, and compiler characteristics.

 AC_HEADER_STDBOOL

 AC_C_CONST

 dnl Checks for library functions.

 AC_CHECK_FUNCS([setlocale sqrt])

 AC_CONFIG_FILES([

 Makefile

 glemon.spec

 autopackage/default.apspec

 po/Makefile.in

 m4/Makefile

 ])

 AC_OUTPUT

 echo

 echo '****************************** SUMMARY ******************************'

 echo

 echo Package version............... : $PACKAGE-$VERSION

 echo

 echo C++ compiler.................. : $CXX

 echo C++ compiles flags............ : $CXXFLAGS

 echo

 echo LEMON CFLAGS.................. : $LEMON_CFLAGS

 echo LEMON LIBS.................... : $LEMON_LIBS

 echo

 echo The packace will be installed in

 echo -n '  '

 echo $prefix.

 echo

 echo '*********************************************************************'

 echo

 echo configure complete, now type \'make\' and then \'make install\'.

 echo