lemon-main: m4/lx_check_soplex.m4@b95898314e09

     1 AC_DEFUN([LX_CHECK_SOPLEX],

2 [

     3   AC_ARG_WITH([soplex],

     4 AS_HELP_STRING([--with-soplex@<:@=PREFIX@:>@], [search for SOPLEX under PREFIX or under the default search paths if PREFIX is not given @<:@default@:>@])

     5 AS_HELP_STRING([--without-soplex], [disable checking for SOPLEX]),

     6               [], [with_soplex=yes])

     8   AC_ARG_WITH([soplex-includedir],

     9 AS_HELP_STRING([--with-soplex-includedir=DIR], [search for SOPLEX headers in DIR]),

    10               [], [with_soplex_includedir=no])

    12   AC_ARG_WITH([soplex-libdir],

    13 AS_HELP_STRING([--with-soplex-libdir=DIR], [search for SOPLEX libraries in DIR]),

    14               [], [with_soplex_libdir=no])

    16   lx_soplex_found=no

    17   if test x"$with_soplex" != x"no"; then

    18     AC_MSG_CHECKING([for SOPLEX])

    20     if test x"$with_soplex_includedir" != x"no"; then

    21       SOPLEX_CXXFLAGS="-I$with_soplex_includedir"

    22     elif test x"$with_soplex" != x"yes"; then

    23       SOPLEX_CXXFLAGS="-I$with_soplex/src"

    24     fi

    26     if test x"$with_soplex_libdir" != x"no"; then

    27       SOPLEX_LDFLAGS="-L$with_soplex_libdir"

    28     elif test x"$with_soplex" != x"yes"; then

    29       SOPLEX_LDFLAGS="-L$with_soplex/lib"

    30     fi

    31     SOPLEX_LIBS="-lsoplex -lz"

    33     lx_save_cxxflags="$CXXFLAGS"

    34     lx_save_ldflags="$LDFLAGS"

    35     lx_save_libs="$LIBS"

    36     CXXFLAGS="$SOPLEX_CXXFLAGS"

    37     LDFLAGS="$SOPLEX_LDFLAGS"

    38     LIBS="$SOPLEX_LIBS"

    40     lx_soplex_test_prog='

    41       #include <soplex.h>

    43       int main(int argc, char** argv)

    44       {

    45         soplex::SoPlex soplex;

    46         return 0;

    47       }'

    49     AC_LANG_PUSH(C++)

    50     AC_LINK_IFELSE([$lx_soplex_test_prog], [lx_soplex_found=yes], [lx_soplex_found=no])

    51     AC_LANG_POP(C++)

    53     CXXFLAGS="$lx_save_cxxflags"

    54     LDFLAGS="$lx_save_ldflags"

    55     LIBS="$lx_save_libs"

    57     if test x"$lx_soplex_found" = x"yes"; then

    58       AC_DEFINE([HAVE_SOPLEX], [1], [Define to 1 if you have SOPLEX.])

    59       lx_lp_found=yes

    60       AC_DEFINE([HAVE_LP], [1], [Define to 1 if you have any LP solver.])

    61       AC_MSG_RESULT([yes])

    62     else

    63       SOPLEX_CXXFLAGS=""

    64       SOPLEX_LDFLAGS=""

    65       SOPLEX_LIBS=""

    66       AC_MSG_RESULT([no])

    67     fi

    68   fi

    69   SOPLEX_LIBS="$SOPLEX_LDFLAGS $SOPLEX_LIBS"

    70   AC_SUBST(SOPLEX_CXXFLAGS)

    71   AC_SUBST(SOPLEX_LIBS)

    72   AM_CONDITIONAL([HAVE_SOPLEX], [test x"$lx_soplex_found" = x"yes"])

    73 ])

author	Alpar Juttner <alpar@cs.elte.hu>
	Fri, 24 Apr 2009 12:12:14 +0100
changeset 618	b95898314e09
parent 457	69928a704ffb
child 627	20dac2104519
permissions	-rw-r--r--