alpar@9: /* MAGIC, Magic Square */
alpar@9: 
alpar@9: /* Written in GNU MathProg by Andrew Makhorin <mao@gnu.org> */
alpar@9: 
alpar@9: /* In recreational mathematics, a magic square of order n is an
alpar@9:    arrangement of n^2 numbers, usually distinct integers, in a square,
alpar@9:    such that n numbers in all rows, all columns, and both diagonals sum
alpar@9:    to the same constant. A normal magic square contains the integers
alpar@9:    from 1 to n^2.
alpar@9: 
alpar@9:    (From Wikipedia, the free encyclopedia.) */
alpar@9: 
alpar@9: param n, integer, > 0, default 4;
alpar@9: /* square order */
alpar@9: 
alpar@9: set N := 1..n^2;
alpar@9: /* integers to be placed */
alpar@9: 
alpar@9: var x{i in 1..n, j in 1..n, k in N}, binary;
alpar@9: /* x[i,j,k] = 1 means that cell (i,j) contains integer k */
alpar@9: 
alpar@9: s.t. a{i in 1..n, j in 1..n}: sum{k in N} x[i,j,k] = 1;
alpar@9: /* each cell must be assigned exactly one integer */
alpar@9: 
alpar@9: s.t. b{k in N}: sum{i in 1..n, j in 1..n} x[i,j,k] = 1;
alpar@9: /* each integer must be assigned exactly to one cell */
alpar@9: 
alpar@9: var s;
alpar@9: /* the magic sum */
alpar@9: 
alpar@9: s.t. r{i in 1..n}: sum{j in 1..n, k in N} k * x[i,j,k] = s;
alpar@9: /* the sum in each row must be the magic sum */
alpar@9: 
alpar@9: s.t. c{j in 1..n}: sum{i in 1..n, k in N} k * x[i,j,k] = s;
alpar@9: /* the sum in each column must be the magic sum */
alpar@9: 
alpar@9: s.t. d: sum{i in 1..n, k in N} k * x[i,i,k] = s;
alpar@9: /* the sum in the diagonal must be the magic sum */
alpar@9: 
alpar@9: s.t. e: sum{i in 1..n, k in N} k * x[i,n-i+1,k] = s;
alpar@9: /* the sum in the co-diagonal must be the magic sum */
alpar@9: 
alpar@9: solve;
alpar@9: 
alpar@9: printf "\n";
alpar@9: printf "Magic sum is %d\n", s;
alpar@9: printf "\n";
alpar@9: for{i in 1..n}
alpar@9: {  printf{j in 1..n} "%3d", sum{k in N} k * x[i,j,k];
alpar@9:    printf "\n";
alpar@9: }
alpar@9: printf "\n";
alpar@9: 
alpar@9: end;