alpar@9: /* SUDOKU, Number Placement Puzzle */
alpar@9: 
alpar@9: /* Written in GNU MathProg by Andrew Makhorin <mao@gnu.org> */
alpar@9: 
alpar@9: /* Sudoku, also known as Number Place, is a logic-based placement
alpar@9:    puzzle. The aim of the canonical puzzle is to enter a numerical
alpar@9:    digit from 1 through 9 in each cell of a 9x9 grid made up of 3x3
alpar@9:    subgrids (called "regions"), starting with various digits given in
alpar@9:    some cells (the "givens"). Each row, column, and region must contain
alpar@9:    only one instance of each numeral.
alpar@9: 
alpar@9:    Example:
alpar@9: 
alpar@9:    +-------+-------+-------+
alpar@9:    | 5 3 . | . 7 . | . . . |
alpar@9:    | 6 . . | 1 9 5 | . . . |
alpar@9:    | . 9 8 | . . . | . 6 . |
alpar@9:    +-------+-------+-------+
alpar@9:    | 8 . . | . 6 . | . . 3 |
alpar@9:    | 4 . . | 8 . 3 | . . 1 |
alpar@9:    | 7 . . | . 2 . | . . 6 |
alpar@9:    +-------+-------+-------+
alpar@9:    | . 6 . | . . . | 2 8 . |
alpar@9:    | . . . | 4 1 9 | . . 5 |
alpar@9:    | . . . | . 8 . | . 7 9 |
alpar@9:    +-------+-------+-------+
alpar@9: 
alpar@9:    (From Wikipedia, the free encyclopedia.) */
alpar@9: 
alpar@9: param givens{1..9, 1..9}, integer, >= 0, <= 9, default 0;
alpar@9: /* the "givens" */
alpar@9: 
alpar@9: var x{i in 1..9, j in 1..9, k in 1..9}, binary;
alpar@9: /* x[i,j,k] = 1 means cell [i,j] is assigned number k */
alpar@9: 
alpar@9: s.t. fa{i in 1..9, j in 1..9, k in 1..9: givens[i,j] != 0}:
alpar@9:      x[i,j,k] = (if givens[i,j] = k then 1 else 0);
alpar@9: /* assign pre-defined numbers using the "givens" */
alpar@9: 
alpar@9: s.t. fb{i in 1..9, j in 1..9}: sum{k in 1..9} x[i,j,k] = 1;
alpar@9: /* each cell must be assigned exactly one number */
alpar@9: 
alpar@9: s.t. fc{i in 1..9, k in 1..9}: sum{j in 1..9} x[i,j,k] = 1;
alpar@9: /* cells in the same row must be assigned distinct numbers */
alpar@9: 
alpar@9: s.t. fd{j in 1..9, k in 1..9}: sum{i in 1..9} x[i,j,k] = 1;
alpar@9: /* cells in the same column must be assigned distinct numbers */
alpar@9: 
alpar@9: s.t. fe{I in 1..9 by 3, J in 1..9 by 3, k in 1..9}:
alpar@9:      sum{i in I..I+2, j in J..J+2} x[i,j,k] = 1;
alpar@9: /* cells in the same region must be assigned distinct numbers */
alpar@9: 
alpar@9: /* there is no need for an objective function here */
alpar@9: 
alpar@9: solve;
alpar@9: 
alpar@9: for {i in 1..9}
alpar@9: {  for {0..0: i = 1 or i = 4 or i = 7}
alpar@9:       printf " +-------+-------+-------+\n";
alpar@9:    for {j in 1..9}
alpar@9:    {  for {0..0: j = 1 or j = 4 or j = 7} printf(" |");
alpar@9:       printf " %d", sum{k in 1..9} x[i,j,k] * k;
alpar@9:       for {0..0: j = 9} printf(" |\n");
alpar@9:    }
alpar@9:    for {0..0: i = 9}
alpar@9:       printf " +-------+-------+-------+\n";
alpar@9: }
alpar@9: 
alpar@9: data;
alpar@9: 
alpar@9: /* These data correspond to the example above. */
alpar@9: 
alpar@9: param givens : 1 2 3 4 5 6 7 8 9 :=
alpar@9:            1   5 3 . . 7 . . . .
alpar@9:            2   6 . . 1 9 5 . . .
alpar@9:            3   . 9 8 . . . . 6 .
alpar@9:            4   8 . . . 6 . . . 3
alpar@9:            5   4 . . 8 . 3 . . 1
alpar@9:            6   7 . . . 2 . . . 6
alpar@9:            7   . 6 . . . . 2 8 .
alpar@9:            8   . . . 4 1 9 . . 5
alpar@9:            9   . . . . 8 . . 7 9 ;
alpar@9: 
alpar@9: end;