lemon: CMakeLists.txt@5de6a70446f6

     1 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)

     3 IF(POLICY CMP0048)

     4   CMAKE_POLICY(SET CMP0048 OLD)

     5 ENDIF(POLICY CMP0048)

     7 SET(PROJECT_NAME "LEMON")

     8 PROJECT(${PROJECT_NAME})

    10 INCLUDE(FindPythonInterp)

    11 INCLUDE(FindWget)

    13 IF(EXISTS ${PROJECT_SOURCE_DIR}/cmake/version.cmake)

    14   INCLUDE(${PROJECT_SOURCE_DIR}/cmake/version.cmake)

    15 ELSEIF(DEFINED ENV{LEMON_VERSION})

    16   SET(LEMON_VERSION $ENV{LEMON_VERSION} CACHE STRING "LEMON version string.")

    17 ELSE()

    18   EXECUTE_PROCESS(

    19     COMMAND

    20     hg log -r. --template "{latesttag}"

    21     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}

    22     OUTPUT_VARIABLE HG_REVISION_TAG

    23     ERROR_QUIET

    24     OUTPUT_STRIP_TRAILING_WHITESPACE

    25   )

    26   EXECUTE_PROCESS(

    27     COMMAND

    28     hg log -r. --template "{latesttagdistance}"

    29     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}

    30     OUTPUT_VARIABLE HG_REVISION_DIST

    31     ERROR_QUIET

    32     OUTPUT_STRIP_TRAILING_WHITESPACE

    33   )

    34   EXECUTE_PROCESS(

    35     COMMAND

    36     hg log -r. --template "{node|short}"

    37     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}

    38     OUTPUT_VARIABLE HG_REVISION_ID

    39     ERROR_QUIET

    40     OUTPUT_STRIP_TRAILING_WHITESPACE

    41   )

    43   IF(HG_REVISION_TAG STREQUAL "")

    44     SET(HG_REVISION_ID "hg-tip")

    45   ELSE()

    46     IF(HG_REVISION_TAG STREQUAL "null")

    47       SET(HG_REVISION_TAG "trunk")

    48     ELSEIF(HG_REVISION_TAG MATCHES "^r")

    49       STRING(SUBSTRING ${HG_REVISION_TAG} 1 -1 HG_REVISION_TAG)

    50     ENDIF()

    51     IF(HG_REVISION_DIST STREQUAL "0")

    52       SET(HG_REVISION ${HG_REVISION_TAG})

    53     ELSE()

    54       SET(HG_REVISION

    55 	"${HG_REVISION_TAG}+${HG_REVISION_DIST}-${HG_REVISION_ID}")

    56     ENDIF()

    57   ENDIF()

    59   SET(LEMON_VERSION ${HG_REVISION} CACHE STRING "LEMON version string.")

    60 ENDIF()

    62 SET(PROJECT_VERSION ${LEMON_VERSION})

    64 SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)

    66 FIND_PACKAGE(Doxygen)

    67 FIND_PACKAGE(Ghostscript)

    69 SET(LEMON_ENABLE_GLPK YES CACHE STRING "Enable GLPK solver backend.")

    70 SET(LEMON_ENABLE_ILOG YES CACHE STRING "Enable ILOG (CPLEX) solver backend.")

    71 SET(LEMON_ENABLE_COIN YES CACHE STRING "Enable COIN solver backend.")

    72 SET(LEMON_ENABLE_SOPLEX YES CACHE STRING "Enable SoPlex solver backend.")

    74 IF(LEMON_ENABLE_GLPK)

    75   FIND_PACKAGE(GLPK 4.33)

    76 ENDIF(LEMON_ENABLE_GLPK)

    77 IF(LEMON_ENABLE_ILOG)

    78   FIND_PACKAGE(ILOG)

    79 ENDIF(LEMON_ENABLE_ILOG)

    80 IF(LEMON_ENABLE_COIN)

    81   FIND_PACKAGE(COIN)

    82 ENDIF(LEMON_ENABLE_COIN)

    83 IF(LEMON_ENABLE_SOPLEX)

    84   FIND_PACKAGE(SOPLEX)

    85 ENDIF(LEMON_ENABLE_SOPLEX)

    87 IF(GLPK_FOUND)

    88   SET(LEMON_HAVE_LP TRUE)

    89   SET(LEMON_HAVE_MIP TRUE)

    90   SET(LEMON_HAVE_GLPK TRUE)

    91 ENDIF(GLPK_FOUND)

    92 IF(ILOG_FOUND)

    93   SET(LEMON_HAVE_LP TRUE)

    94   SET(LEMON_HAVE_MIP TRUE)

    95   SET(LEMON_HAVE_CPLEX TRUE)

    96 ENDIF(ILOG_FOUND)

    97 IF(COIN_FOUND)

    98   SET(LEMON_HAVE_LP TRUE)

    99   SET(LEMON_HAVE_MIP TRUE)

   100   SET(LEMON_HAVE_CLP TRUE)

   101   SET(LEMON_HAVE_CBC TRUE)

   102 ENDIF(COIN_FOUND)

   103 IF(SOPLEX_FOUND)

   104   SET(LEMON_HAVE_LP TRUE)

   105   SET(LEMON_HAVE_SOPLEX TRUE)

   106 ENDIF(SOPLEX_FOUND)

   108 IF(ILOG_FOUND)

   109   SET(DEFAULT_LP "CPLEX")

   110   SET(DEFAULT_MIP "CPLEX")

   111 ELSEIF(COIN_FOUND)

   112   SET(DEFAULT_LP "CLP")

   113   SET(DEFAULT_MIP "CBC")

   114 ELSEIF(GLPK_FOUND)

   115   SET(DEFAULT_LP "GLPK")

   116   SET(DEFAULT_MIP "GLPK")

   117 ELSEIF(SOPLEX_FOUND)

   118   SET(DEFAULT_LP "SOPLEX")

   119 ENDIF()

   121 IF(NOT LEMON_DEFAULT_LP OR

   122     (NOT ILOG_FOUND AND (LEMON_DEFAULT_LP STREQUAL "CPLEX")) OR

   123     (NOT COIN_FOUND AND (LEMON_DEFAULT_LP STREQUAL "CLP")) OR

   124     (NOT GLPK_FOUND AND (LEMON_DEFAULT_LP STREQUAL "GLPK")) OR

   125     (NOT SOPLEX_FOUND AND (LEMON_DEFAULT_LP STREQUAL "SOPLEX")))

   126   SET(LEMON_DEFAULT_LP ${DEFAULT_LP} CACHE STRING

   127     "Default LP solver backend (GLPK, CPLEX, CLP or SOPLEX)" FORCE)

   128 ELSE()

   129   SET(LEMON_DEFAULT_LP ${DEFAULT_LP} CACHE STRING

   130     "Default LP solver backend (GLPK, CPLEX, CLP or SOPLEX)")

   131 ENDIF()

   132 IF(NOT LEMON_DEFAULT_MIP OR

   133     (NOT ILOG_FOUND AND (LEMON_DEFAULT_MIP STREQUAL "CPLEX")) OR

   134     (NOT COIN_FOUND AND (LEMON_DEFAULT_MIP STREQUAL "CBC")) OR

   135     (NOT GLPK_FOUND AND (LEMON_DEFAULT_MIP STREQUAL "GLPK")))

   136   SET(LEMON_DEFAULT_MIP ${DEFAULT_MIP} CACHE STRING

   137     "Default MIP solver backend (GLPK, CPLEX or CBC)" FORCE)

   138 ELSE()

   139   SET(LEMON_DEFAULT_MIP ${DEFAULT_MIP} CACHE STRING

   140     "Default MIP solver backend (GLPK, CPLEX or CBC)")

   141 ENDIF()

   144 IF(DEFINED ENV{LEMON_CXX_WARNING})

   145   SET(CXX_WARNING $ENV{LEMON_CXX_WARNING})

   146 ELSE()

   147   IF(CMAKE_COMPILER_IS_GNUCXX)

   148     SET(CXX_WARNING "-Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas")

   149     SET(CMAKE_CXX_FLAGS_DEBUG CACHE STRING "-ggdb")

   150     SET(CMAKE_C_FLAGS_DEBUG CACHE STRING "-ggdb")

   151   ELSEIF(MSVC)

   152     # This part is unnecessary 'casue the same is set by the lemon/core.h.

   153     # Still keep it as an example.

   154     SET(CXX_WARNING "/wd4250 /wd4355 /wd4503 /wd4800 /wd4996")

   155     # Suppressed warnings:

   156     # C4250: 'class1' : inherits 'class2::member' via dominance

   157     # C4355: 'this' : used in base member initializer list

   158     # C4503: 'function' : decorated name length exceeded, name was truncated

   159     # C4800: 'type' : forcing value to bool 'true' or 'false'

   160     #        (performance warning)

   161     # C4996: 'function': was declared deprecated

   162   ELSE()

   163     SET(CXX_WARNING "-Wall")

   164   ENDIF()

   165 ENDIF()

   166 SET(LEMON_CXX_WARNING_FLAGS ${CXX_WARNING} CACHE STRING "LEMON warning flags.")

   168 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LEMON_CXX_WARNING_FLAGS}")

   170 IF(MSVC)

   171   SET( CMAKE_CXX_FLAGS_MAINTAINER "/WX ${CMAKE_CXX_FLAGS_DEBUG}" CACHE STRING

   172     "Flags used by the C++ compiler during maintainer builds."

   173     )

   174   SET( CMAKE_C_FLAGS_MAINTAINER "/WX ${CMAKE_CXX_FLAGS_DEBUG}" CACHE STRING

   175     "Flags used by the C compiler during maintainer builds."

   176     )

   177   SET( CMAKE_EXE_LINKER_FLAGS_MAINTAINER

   178     "${CMAKE_EXE_LINKER_FLAGS_DEBUG}" CACHE STRING

   179     "Flags used for linking binaries during maintainer builds."

   180     )

   181   SET( CMAKE_SHARED_LINKER_FLAGS_MAINTAINER

   182     "${CMAKE_SHARED_LINKER_FLAGS_DEBUG}" CACHE STRING

   183     "Flags used by the shared libraries linker during maintainer builds."

   184     )

   185 ELSE()

   186   SET( CMAKE_CXX_FLAGS_MAINTAINER "-Werror -ggdb -O0" CACHE STRING

   187     "Flags used by the C++ compiler during maintainer builds."

   188     )

   189   SET( CMAKE_C_FLAGS_MAINTAINER "-Werror -O0" CACHE STRING

   190     "Flags used by the C compiler during maintainer builds."

   191     )

   192   SET( CMAKE_EXE_LINKER_FLAGS_MAINTAINER

   193     "${CMAKE_EXE_LINKER_FLAGS_DEBUG}" CACHE STRING

   194     "Flags used for linking binaries during maintainer builds."

   195     )

   196   SET( CMAKE_SHARED_LINKER_FLAGS_MAINTAINER

   197     "${CMAKE_SHARED_LINKER_FLAGS_DEBUG}" CACHE STRING

   198     "Flags used by the shared libraries linker during maintainer builds."

   199     )

   200 ENDIF()

   202 MARK_AS_ADVANCED(

   203     CMAKE_CXX_FLAGS_MAINTAINER

   204     CMAKE_C_FLAGS_MAINTAINER

   205     CMAKE_EXE_LINKER_FLAGS_MAINTAINER

   206     CMAKE_SHARED_LINKER_FLAGS_MAINTAINER )

   208 IF(CMAKE_CONFIGURATION_TYPES)

   209   LIST(APPEND CMAKE_CONFIGURATION_TYPES Maintainer)

   210   LIST(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)

   211   SET(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING

   212       "Add the configurations that we need"

   213       FORCE)

   214  endif()

   216 IF(NOT CMAKE_BUILD_TYPE)

   217   SET(CMAKE_BUILD_TYPE "Release")

   218 ENDIF()

   220 SET( CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING

   221     "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel Maintainer."

   222     FORCE )

   225 INCLUDE(CheckTypeSize)

   226 CHECK_TYPE_SIZE("long long" LONG_LONG)

   227 SET(LEMON_HAVE_LONG_LONG ${HAVE_LONG_LONG})

   229 INCLUDE(FindThreads)

   231 IF(NOT LEMON_THREADING)

   232   IF(CMAKE_USE_PTHREADS_INIT)

   233     SET(LEMON_THREADING "Pthread")

   234   ELSEIF(CMAKE_USE_WIN32_THREADS_INIT)

   235     SET(LEMON_THREADING "Win32")

   236   ELSE()

   237     SET(LEMON_THREADING "None")

   238   ENDIF()

   239 ENDIF()

   241 SET( LEMON_THREADING "${LEMON_THREADING}" CACHE STRING

   242   "Choose the threading library, options are: Pthread Win32 None."

   243   FORCE )

   245 IF(LEMON_THREADING STREQUAL "Pthread")

   246   SET(LEMON_USE_PTHREAD TRUE)

   247 ELSEIF(LEMON_THREADING STREQUAL "Win32")

   248   SET(LEMON_USE_WIN32_THREADS TRUE)

   249 ENDIF()

   251 ENABLE_TESTING()

   253 IF(${CMAKE_BUILD_TYPE} STREQUAL "Maintainer")

   254   ADD_CUSTOM_TARGET(check ALL COMMAND ${CMAKE_CTEST_COMMAND})

   255 ELSE()

   256   ADD_CUSTOM_TARGET(check COMMAND ${CMAKE_CTEST_COMMAND})

   257 ENDIF()

   259 ADD_SUBDIRECTORY(lemon)

   260 IF(${CMAKE_SOURCE_DIR} STREQUAL ${PROJECT_SOURCE_DIR})

   261   ADD_SUBDIRECTORY(contrib)

   262   ADD_SUBDIRECTORY(demo)

   263   ADD_SUBDIRECTORY(tools)

   264   ADD_SUBDIRECTORY(doc)

   265   ADD_SUBDIRECTORY(test)

   266 ENDIF()

   268 CONFIGURE_FILE(

   269   ${PROJECT_SOURCE_DIR}/cmake/LEMONConfig.cmake.in

   270   ${PROJECT_BINARY_DIR}/cmake/LEMONConfig.cmake

   271   @ONLY

   272 )

   273 IF(UNIX)

   274   INSTALL(

   275     FILES ${PROJECT_BINARY_DIR}/cmake/LEMONConfig.cmake

   276     DESTINATION share/lemon/cmake

   277   )

   278 ELSEIF(WIN32)

   279   INSTALL(

   280     FILES ${PROJECT_BINARY_DIR}/cmake/LEMONConfig.cmake

   281     DESTINATION cmake

   282   )

   283 ENDIF()

   285 CONFIGURE_FILE(

   286   ${PROJECT_SOURCE_DIR}/cmake/version.cmake.in

   287   ${PROJECT_BINARY_DIR}/cmake/version.cmake

   288   @ONLY

   289 )

   291 SET(ARCHIVE_BASE_NAME ${CMAKE_PROJECT_NAME})

   292 STRING(TOLOWER ${ARCHIVE_BASE_NAME} ARCHIVE_BASE_NAME)

   293 SET(ARCHIVE_NAME ${ARCHIVE_BASE_NAME}-${PROJECT_VERSION})

   294 ADD_CUSTOM_TARGET(dist

   295   COMMAND cmake -E remove_directory ${ARCHIVE_NAME}

   296   COMMAND hg archive ${ARCHIVE_NAME}

   297   COMMAND cmake -E copy cmake/version.cmake ${ARCHIVE_NAME}/cmake/version.cmake

   298   COMMAND tar -czf ${ARCHIVE_BASE_NAME}-nodoc-${PROJECT_VERSION}.tar.gz ${ARCHIVE_NAME}

   299   COMMAND zip -r ${ARCHIVE_BASE_NAME}-nodoc-${PROJECT_VERSION}.zip ${ARCHIVE_NAME}

   300   COMMAND cmake -E copy_directory doc/html ${ARCHIVE_NAME}/doc/html

   301   COMMAND tar -czf ${ARCHIVE_NAME}.tar.gz ${ARCHIVE_NAME}

   302   COMMAND zip -r ${ARCHIVE_NAME}.zip ${ARCHIVE_NAME}

   303   COMMAND cmake -E copy_directory doc/html ${ARCHIVE_BASE_NAME}-doc-${PROJECT_VERSION}

   304   COMMAND tar -czf ${ARCHIVE_BASE_NAME}-doc-${PROJECT_VERSION}.tar.gz ${ARCHIVE_BASE_NAME}-doc-${PROJECT_VERSION}

   305   COMMAND zip -r ${ARCHIVE_BASE_NAME}-doc-${PROJECT_VERSION}.zip ${ARCHIVE_BASE_NAME}-doc-${PROJECT_VERSION}

   306   COMMAND cmake -E remove_directory ${ARCHIVE_NAME}

   307   COMMAND cmake -E remove_directory ${ARCHIVE_BASE_NAME}-doc-${PROJECT_VERSION}

   308   DEPENDS html

   309   WORKING_DIRECTORY ${PROJECT_BINARY_DIR})

   311 # CPACK config (Basically for NSIS)

   312 IF(${CMAKE_SOURCE_DIR} STREQUAL ${PROJECT_SOURCE_DIR})

   313   SET(CPACK_PACKAGE_NAME ${PROJECT_NAME})

   314   SET(CPACK_PACKAGE_VENDOR "EGRES")

   315   SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY

   316     "LEMON - Library for Efficient Modeling and Optimization in Networks")

   317   SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/LICENSE")

   319   SET(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})

   321   SET(CPACK_PACKAGE_INSTALL_DIRECTORY

   322     "${PROJECT_NAME} ${PROJECT_VERSION}")

   323   SET(CPACK_PACKAGE_INSTALL_REGISTRY_KEY

   324     "${PROJECT_NAME} ${PROJECT_VERSION}")

   326   SET(CPACK_COMPONENTS_ALL headers library html_documentation bin)

   328   SET(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ headers")

   329   SET(CPACK_COMPONENT_LIBRARY_DISPLAY_NAME "Dynamic-link library")

   330   SET(CPACK_COMPONENT_BIN_DISPLAY_NAME "Command line utilities")

   331   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_DISPLAY_NAME "HTML documentation")

   333   SET(CPACK_COMPONENT_HEADERS_DESCRIPTION

   334     "C++ header files")

   335   SET(CPACK_COMPONENT_LIBRARY_DESCRIPTION

   336     "DLL and import library")

   337   SET(CPACK_COMPONENT_BIN_DESCRIPTION

   338     "Command line utilities")

   339   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_DESCRIPTION

   340     "Doxygen generated documentation")

   342   SET(CPACK_COMPONENT_HEADERS_DEPENDS library)

   344   SET(CPACK_COMPONENT_HEADERS_GROUP "Development")

   345   SET(CPACK_COMPONENT_LIBRARY_GROUP "Development")

   346   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_GROUP "Documentation")

   348   SET(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION

   349     "Components needed to develop software using LEMON")

   350   SET(CPACK_COMPONENT_GROUP_DOCUMENTATION_DESCRIPTION

   351     "Documentation of LEMON")

   353   SET(CPACK_ALL_INSTALL_TYPES Full Developer)

   355   SET(CPACK_COMPONENT_HEADERS_INSTALL_TYPES Developer Full)

   356   SET(CPACK_COMPONENT_LIBRARY_INSTALL_TYPES Developer Full)

   357   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_INSTALL_TYPES Full)

   359   SET(CPACK_GENERATOR "NSIS")

   360   SET(CPACK_NSIS_MUI_ICON "${PROJECT_SOURCE_DIR}/cmake/nsis/lemon.ico")

   361   SET(CPACK_NSIS_MUI_UNIICON "${PROJECT_SOURCE_DIR}/cmake/nsis/uninstall.ico")

   362   #SET(CPACK_PACKAGE_ICON "${PROJECT_SOURCE_DIR}/cmake/nsis\\\\installer.bmp")

   363   SET(CPACK_NSIS_INSTALLED_ICON_NAME "bin\\\\lemon.ico")

   364   SET(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY} ${PROJECT_NAME}")

   365   SET(CPACK_NSIS_HELP_LINK "http:\\\\\\\\lemon.cs.elte.hu")

   366   SET(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\lemon.cs.elte.hu")

   367   SET(CPACK_NSIS_CONTACT "lemon-user@lemon.cs.elte.hu")

   368   SET(CPACK_NSIS_CREATE_ICONS_EXTRA "

   369     CreateShortCut \\\"$SMPROGRAMS\\\\$STARTMENU_FOLDER\\\\Documentation.lnk\\\" \\\"$INSTDIR\\\\share\\\\doc\\\\index.html\\\"

   370     ")

   371   SET(CPACK_NSIS_DELETE_ICONS_EXTRA "

   372     !insertmacro MUI_STARTMENU_GETFOLDER Application $MUI_TEMP

   373     Delete \\\"$SMPROGRAMS\\\\$MUI_TEMP\\\\Documentation.lnk\\\"

   374     ")

   376   INCLUDE(CPack)

   377 ENDIF()

author	Alpar Juttner <alpar@cs.elte.hu>
	Wed, 09 Jul 2014 14:41:36 +0200
changeset 1323	5de6a70446f6
parent 1313	fe4ff72e2f14
child 1326	f05270f176d9
permissions	-rw-r--r--