lemon: CMakeLists.txt@eb12ad2789fc

     1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)

     3 SET(PROJECT_NAME "LEMON")

     4 PROJECT(${PROJECT_NAME})

     6 INCLUDE(FindPythonInterp)

     7 INCLUDE(FindWget)

     9 IF(EXISTS ${PROJECT_SOURCE_DIR}/cmake/version.cmake)

    10   INCLUDE(${PROJECT_SOURCE_DIR}/cmake/version.cmake)

    11 ELSEIF(DEFINED ENV{LEMON_VERSION})

    12   SET(LEMON_VERSION $ENV{LEMON_VERSION} CACHE STRING "LEMON version string.")

    13 ELSE()

    14   EXECUTE_PROCESS(

    15     COMMAND ${PYTHON_EXECUTABLE} ./scripts/chg-len.py

    16     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}

    17     OUTPUT_VARIABLE HG_REVISION_PATH

    18     ERROR_QUIET

    19     OUTPUT_STRIP_TRAILING_WHITESPACE

    20   )

    21   EXECUTE_PROCESS(

    22     COMMAND hg id -i

    23     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}

    24     OUTPUT_VARIABLE HG_REVISION

    25     ERROR_QUIET

    26     OUTPUT_STRIP_TRAILING_WHITESPACE

    27   )

    28   IF(HG_REVISION STREQUAL "")

    29     SET(HG_REVISION_ID "hg-tip")

    30   ELSE()

    31     IF(HG_REVISION_PATH STREQUAL "")

    32       SET(HG_REVISION_ID ${HG_REVISION})

    33     ELSE()

    34       SET(HG_REVISION_ID ${HG_REVISION_PATH}.${HG_REVISION})

    35     ENDIF()

    36   ENDIF()

    37   SET(LEMON_VERSION ${HG_REVISION_ID} CACHE STRING "LEMON version string.")

    38 ENDIF()

    40 SET(PROJECT_VERSION ${LEMON_VERSION})

    42 SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)

    44 FIND_PACKAGE(Doxygen)

    45 FIND_PACKAGE(Ghostscript)

    46 FIND_PACKAGE(GLPK 4.33)

    47 FIND_PACKAGE(CPLEX)

    48 FIND_PACKAGE(COIN)

    50 IF(DEFINED ENV{LEMON_CXX_WARNING})

    51   SET(CXX_WARNING $ENV{LEMON_CXX_WARNING})

    52 ELSE()

    53   IF(CMAKE_COMPILER_IS_GNUCXX)

    54     SET(CXX_WARNING "-Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas")

    55     SET(CMAKE_CXX_FLAGS_DEBUG CACHE STRING "-ggdb")

    56     SET(CMAKE_C_FLAGS_DEBUG CACHE STRING "-ggdb")

    57   ELSEIF(MSVC)

    58     # This part is unnecessary 'casue the same is set by the lemon/core.h.

    59     # Still keep it as an example.

    60     SET(CXX_WARNING "/wd4250 /wd4355 /wd4503 /wd4800 /wd4996")

    61     # Suppressed warnings:

    62     # C4250: 'class1' : inherits 'class2::member' via dominance

    63     # C4355: 'this' : used in base member initializer list

    64     # C4503: 'function' : decorated name length exceeded, name was truncated

    65     # C4800: 'type' : forcing value to bool 'true' or 'false'

    66     #        (performance warning)

    67     # C4996: 'function': was declared deprecated

    68   ELSE()

    69     SET(CXX_WARNING "-Wall")

    70   ENDIF()

    71 ENDIF()

    72 SET(LEMON_CXX_WARNING_FLAGS ${CXX_WARNING} CACHE STRING "LEMON warning flags.")

    74 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LEMON_CXX_WARNING_FLAGS}")

    76 SET( CMAKE_CXX_FLAGS_MAINTAINER "-Werror -ggdb -O0" CACHE STRING

    77     "Flags used by the C++ compiler during maintainer builds."

    78     FORCE )

    79 SET( CMAKE_C_FLAGS_MAINTAINER "-Werror -O0" CACHE STRING

    80     "Flags used by the C compiler during maintainer builds."

    81     FORCE )

    82 SET( CMAKE_EXE_LINKER_FLAGS_MAINTAINER

    83     "-Wl,--warn-unresolved-symbols,--warn-once" CACHE STRING

    84     "Flags used for linking binaries during maintainer builds."

    85     FORCE )

    86 SET( CMAKE_SHARED_LINKER_FLAGS_MAINTAINER

    87     "-Wl,--warn-unresolved-symbols,--warn-once" CACHE STRING

    88     "Flags used by the shared libraries linker during maintainer builds."

    89     FORCE )

    90 MARK_AS_ADVANCED(

    91     CMAKE_CXX_FLAGS_MAINTAINER

    92     CMAKE_C_FLAGS_MAINTAINER

    93     CMAKE_EXE_LINKER_FLAGS_MAINTAINER

    94     CMAKE_SHARED_LINKER_FLAGS_MAINTAINER )

    96 IF(CMAKE_CONFIGURATION_TYPES)

    97   LIST(APPEND CMAKE_CONFIGURATION_TYPES Maintainer)

    98   LIST(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)

    99   SET(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING

   100       "Add the configurations that we need"

   101       FORCE)

   102  endif()

   104 IF(NOT CMAKE_BUILD_TYPE)

   105   SET(CMAKE_BUILD_TYPE "Release")

   106 ENDIF()

   108 SET( CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING

   109     "Choose the type of build, options are: None(CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel Maintainer."

   110     FORCE )

   113 INCLUDE(CheckTypeSize)

   114 CHECK_TYPE_SIZE("long long" LONG_LONG)

   115 SET(LEMON_HAVE_LONG_LONG ${HAVE_LONG_LONG})

   117 INCLUDE(FindThreads)

   119 IF(NOT LEMON_THREADING)

   120   IF(CMAKE_USE_PTHREADS_INIT)

   121     SET(LEMON_THREADING "Pthread")

   122   ELSEIF(CMAKE_USE_WIN32_THREADS_INIT)

   123     SET(LEMON_THREADING "Win32")

   124   ELSE()

   125     SET(LEMON_THREADING "None")

   126   ENDIF()

   127 ENDIF()

   129 SET( LEMON_THREADING "${LEMON_THREADING}" CACHE STRING

   130   "Choose the threading library, options are: Pthread Win32 None."

   131   FORCE )

   133 IF(LEMON_THREADING STREQUAL "Pthread")

   134   SET(LEMON_USE_PTHREAD TRUE)

   135 ELSEIF(LEMON_THREADING STREQUAL "Win32")

   136   SET(LEMON_USE_WIN32_THREADS TRUE)

   137 ENDIF()

   139 ENABLE_TESTING()

   141 IF(${CMAKE_BUILD_TYPE} STREQUAL "Maintainer")

   142   ADD_CUSTOM_TARGET(check ALL COMMAND ${CMAKE_CTEST_COMMAND})

   143 ELSE()

   144   ADD_CUSTOM_TARGET(check COMMAND ${CMAKE_CTEST_COMMAND})

   145 ENDIF()

   147 ADD_SUBDIRECTORY(lemon)

   148 IF(${CMAKE_SOURCE_DIR} STREQUAL ${PROJECT_SOURCE_DIR})

   149   ADD_SUBDIRECTORY(contrib)

   150   ADD_SUBDIRECTORY(demo)

   151   ADD_SUBDIRECTORY(tools)

   152   ADD_SUBDIRECTORY(doc)

   153   ADD_SUBDIRECTORY(test)

   154 ENDIF()

   156 CONFIGURE_FILE(

   157   ${PROJECT_SOURCE_DIR}/cmake/LEMONConfig.cmake.in

   158   ${PROJECT_BINARY_DIR}/cmake/LEMONConfig.cmake

   159   @ONLY

   160 )

   161 IF(UNIX)

   162   INSTALL(

   163     FILES ${PROJECT_BINARY_DIR}/cmake/LEMONConfig.cmake

   164     DESTINATION share/lemon/cmake

   165   )

   166 ELSEIF(WIN32)

   167   INSTALL(

   168     FILES ${PROJECT_BINARY_DIR}/cmake/LEMONConfig.cmake

   169     DESTINATION cmake

   170   )

   171 ENDIF()

   173 IF(${CMAKE_SOURCE_DIR} STREQUAL ${PROJECT_SOURCE_DIR})

   174   SET(CPACK_PACKAGE_NAME ${PROJECT_NAME})

   175   SET(CPACK_PACKAGE_VENDOR "EGRES")

   176   SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY

   177     "LEMON - Library for Efficient Modeling and Optimization in Networks")

   178   SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/LICENSE")

   180   SET(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})

   182   SET(CPACK_PACKAGE_INSTALL_DIRECTORY

   183     "${PROJECT_NAME} ${PROJECT_VERSION}")

   184   SET(CPACK_PACKAGE_INSTALL_REGISTRY_KEY

   185     "${PROJECT_NAME} ${PROJECT_VERSION}")

   187   SET(CPACK_COMPONENTS_ALL headers library html_documentation bin)

   189   SET(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ headers")

   190   SET(CPACK_COMPONENT_LIBRARY_DISPLAY_NAME "Dynamic-link library")

   191   SET(CPACK_COMPONENT_BIN_DISPLAY_NAME "Command line utilities")

   192   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_DISPLAY_NAME "HTML documentation")

   194   SET(CPACK_COMPONENT_HEADERS_DESCRIPTION

   195     "C++ header files")

   196   SET(CPACK_COMPONENT_LIBRARY_DESCRIPTION

   197     "DLL and import library")

   198   SET(CPACK_COMPONENT_BIN_DESCRIPTION

   199     "Command line utilities")

   200   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_DESCRIPTION

   201     "Doxygen generated documentation")

   203   SET(CPACK_COMPONENT_HEADERS_DEPENDS library)

   205   SET(CPACK_COMPONENT_HEADERS_GROUP "Development")

   206   SET(CPACK_COMPONENT_LIBRARY_GROUP "Development")

   207   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_GROUP "Documentation")

   209   SET(CPACK_COMPONENT_GROUP_DEVELOPMENT_DESCRIPTION

   210     "Components needed to develop software using LEMON")

   211   SET(CPACK_COMPONENT_GROUP_DOCUMENTATION_DESCRIPTION

   212     "Documentation of LEMON")

   214   SET(CPACK_ALL_INSTALL_TYPES Full Developer)

   216   SET(CPACK_COMPONENT_HEADERS_INSTALL_TYPES Developer Full)

   217   SET(CPACK_COMPONENT_LIBRARY_INSTALL_TYPES Developer Full)

   218   SET(CPACK_COMPONENT_HTML_DOCUMENTATION_INSTALL_TYPES Full)

   220   SET(CPACK_GENERATOR "NSIS")

   221   SET(CPACK_NSIS_MUI_ICON "${PROJECT_SOURCE_DIR}/cmake/nsis/lemon.ico")

   222   SET(CPACK_NSIS_MUI_UNIICON "${PROJECT_SOURCE_DIR}/cmake/nsis/uninstall.ico")

   223   #SET(CPACK_PACKAGE_ICON "${PROJECT_SOURCE_DIR}/cmake/nsis\\\\installer.bmp")

   224   SET(CPACK_NSIS_INSTALLED_ICON_NAME "bin\\\\lemon.ico")

   225   SET(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY} ${PROJECT_NAME}")

   226   SET(CPACK_NSIS_HELP_LINK "http:\\\\\\\\lemon.cs.elte.hu")

   227   SET(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\lemon.cs.elte.hu")

   228   SET(CPACK_NSIS_CONTACT "lemon-user@lemon.cs.elte.hu")

   229   SET(CPACK_NSIS_CREATE_ICONS_EXTRA "

   230     CreateShortCut \\\"$SMPROGRAMS\\\\$STARTMENU_FOLDER\\\\Documentation.lnk\\\" \\\"$INSTDIR\\\\share\\\\doc\\\\index.html\\\"

   231     ")

   232   SET(CPACK_NSIS_DELETE_ICONS_EXTRA "

   233     !insertmacro MUI_STARTMENU_GETFOLDER Application $MUI_TEMP

   234     Delete \\\"$SMPROGRAMS\\\\$MUI_TEMP\\\\Documentation.lnk\\\"

   235     ")

   237   INCLUDE(CPack)

   238 ENDIF()

author	Peter Kovacs <kpeter@inf.elte.hu>
	Mon, 30 Jan 2012 19:29:03 +0100
changeset 1137	eb12ad2789fc
parent 1131	43a91b33f374
child 1134	0b9a94956916
permissions	-rw-r--r--