source: glemon-0.x/configure.ac @ 144:887cd09ea943

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ([2.59])
AC_INIT([gLEMON], [svn-head], [etik-ol@cs.elte.hu], [glemon])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([-Wall -Werror foreign])
AC_CONFIG_SRCDIR([main_win.h])
AC_CONFIG_HEADERS([config.h])

dnl Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AM_GNU_GETTEXT_VERSION([0.14.2])
AM_GNU_GETTEXT([external])

dnl Checks for libraries.
PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0 gtkmm-2.4 >= 2.6])
PKG_CHECK_MODULES([LEMON_0_5], [lemon >= 0.5],
  [lemon_0_5_found=yes], [
    AC_MSG_RESULT([no])
    lemon_0_5_found=no])
PKG_CHECK_MODULES([LEMON_SVN_HEAD], [lemon = svn-head],
  [lemon_svn_head_found=yes], [
    AC_MSG_RESULT([no])
    lemon_svn_head_found=no])
if test x"$lemon_0_5_found" = x"no" -a x"$lemon_svn_head_found" = x"no"; then
  AC_MSG_ERROR([LEMON not found.])
else
  if test x"$lemon_svn_head_found" = x"yes"; then
    LEMON_CFLAGS="$LEMON_SVN_HEAD_CFLAGS"
    LEMON_LIBS="$LEMON_SVN_HEAD_LIBS"
  else
    LEMON_CFLAGS="$LEMON_0_5_CFLAGS"
    LEMON_LIBS="$LEMON_0_5_LIBS"
  fi
  AC_SUBST(LEMON_CFLAGS)
  AC_SUBST(LEMON_LIBS)
fi

dnl Checks for header files.
AC_CHECK_HEADERS([libintl.h locale.h])

dnl Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST

dnl Checks for library functions.
AC_CHECK_FUNCS([setlocale sqrt])

AC_CONFIG_FILES([
Makefile
po/Makefile.in
m4/Makefile
])

AC_OUTPUT