source: glemon-0.x/configure.ac @ 183:48580778851e

dnl Process this file with autoconf to produce a configure script.

dnl Version information.
m4_define([glemon_version_major], [0])
m4_define([glemon_version_minor], [5])
m4_define([glemon_version_micro], [90])
m4_define([glemon_version_nano], [])
m4_define([glemon_version_tag], [svn])
m4_define([glemon_svn_revision], [m4_normalize(esyscmd([svn info |grep ^Revision |cut -d ' ' -f 2]))])
m4_define([glemon_version], [glemon_version_major().glemon_version_minor()ifelse(glemon_version_micro(), [], [], [.glemon_version_micro()])ifelse(glemon_version_nano(), [], [], [.glemon_version_nano()])ifelse(glemon_version_tag(), [], [], glemon_version_tag(), [svn], [[_]glemon_version_tag()[]glemon_svn_revision()], [[_]glemon_version_tag()])])

AC_PREREQ([2.59])
AC_INIT([gLEMON], [glemon_version()], [etik-ol@cs.elte.hu], [glemon])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([-Wall -Werror foreign])
AC_CONFIG_SRCDIR([main_win.h])
AC_CONFIG_HEADERS([config.h])

dnl Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AM_GNU_GETTEXT_VERSION([0.14.2])
AM_GNU_GETTEXT([external])

dnl Checks for libraries.
PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0 gtkmm-2.4 >= 2.6])

AC_ARG_WITH([lemon-prefix],
AS_HELP_STRING([--with-lemon-prefix@<:@=PREFIX@:>@], [search for LEMON under PREFIX]), [], [with_lemon_prefix=no])
if test x"$with_lemon_prefix" != x"no"; then
  export PKG_CONFIG_PATH="$with_lemon_prefix/lib/pkgconfig/:$PKG_CONFIG_PATH"
fi

PKG_CHECK_MODULES([LEMON_0_5], [lemon >= 0.5],
  [lemon_0_5_found=yes], [
    AC_MSG_RESULT([no])
    lemon_0_5_found=no])
PKG_CHECK_MODULES([LEMON_SVNHEAD], [lemon = svnhead],
  [lemon_svn_head_found=yes], [
    AC_MSG_RESULT([no])
    lemon_svn_head_found=no])
if test x"$lemon_0_5_found" = x"no" -a x"$lemon_svn_head_found" = x"no"; then
  AC_MSG_ERROR([LEMON not found.])
else
  if test x"$lemon_svn_head_found" = x"yes"; then
    LEMON_CFLAGS="$LEMON_SVNHEAD_CFLAGS"
    LEMON_LIBS="$LEMON_SVNHEAD_LIBS"
  else
    LEMON_CFLAGS="$LEMON_0_5_CFLAGS"
    LEMON_LIBS="$LEMON_0_5_LIBS"
  fi
  AC_SUBST(LEMON_CFLAGS)
  AC_SUBST(LEMON_LIBS)
fi

dnl Checks for header files.
AC_CHECK_HEADERS([libintl.h locale.h])

dnl Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST

dnl Checks for library functions.
AC_CHECK_FUNCS([setlocale sqrt])

AC_CONFIG_FILES([
Makefile
glemon.spec
autopackage/default.apspec
po/Makefile.in
m4/Makefile
])

AC_OUTPUT

echo
echo '****************************** SUMMARY ******************************'
echo
echo Package version............... : $PACKAGE-$VERSION
echo
echo C++ compiler.................. : $CXX
echo C++ compiles flags............ : $CXXFLAGS
echo
echo LEMON CFLAGS.................. : $LEMON_CFLAGS
echo LEMON LIBS.................... : $LEMON_LIBS
echo
echo The packace will be installed in
echo -n '  '
echo $prefix.
echo
echo '*********************************************************************'

echo
echo configure complete, now type \'make\' and then \'make install\'.
echo