COIN-OR::LEMON - Graph Library

source: glemon-0.x/configure.ac @ 144:887cd09ea943

Last change on this file since 144:887cd09ea943 was 144:887cd09ea943, checked in by Akos Ladanyi, 14 years ago

Handle 'svn-head' as lemon version.

File size: 1.4 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2AC_PREREQ([2.59])
3AC_INIT([gLEMON], [svn-head], [etik-ol@cs.elte.hu], [glemon])
4AC_CONFIG_AUX_DIR([build-aux])
5AC_CONFIG_MACRO_DIR([m4])
6AM_INIT_AUTOMAKE([-Wall -Werror foreign])
7AC_CONFIG_SRCDIR([main_win.h])
8AC_CONFIG_HEADERS([config.h])
9
10dnl Checks for programs.
11AC_PROG_CXX
12AC_PROG_CC
13AM_GNU_GETTEXT_VERSION([0.14.2])
14AM_GNU_GETTEXT([external])
15
16dnl Checks for libraries.
17PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0 gtkmm-2.4 >= 2.6])
18PKG_CHECK_MODULES([LEMON_0_5], [lemon >= 0.5],
19  [lemon_0_5_found=yes], [
20    AC_MSG_RESULT([no])
21    lemon_0_5_found=no])
22PKG_CHECK_MODULES([LEMON_SVN_HEAD], [lemon = svn-head],
23  [lemon_svn_head_found=yes], [
24    AC_MSG_RESULT([no])
25    lemon_svn_head_found=no])
26if test x"$lemon_0_5_found" = x"no" -a x"$lemon_svn_head_found" = x"no"; then
27  AC_MSG_ERROR([LEMON not found.])
28else
29  if test x"$lemon_svn_head_found" = x"yes"; then
30    LEMON_CFLAGS="$LEMON_SVN_HEAD_CFLAGS"
31    LEMON_LIBS="$LEMON_SVN_HEAD_LIBS"
32  else
33    LEMON_CFLAGS="$LEMON_0_5_CFLAGS"
34    LEMON_LIBS="$LEMON_0_5_LIBS"
35  fi
36  AC_SUBST(LEMON_CFLAGS)
37  AC_SUBST(LEMON_LIBS)
38fi
39
40dnl Checks for header files.
41AC_CHECK_HEADERS([libintl.h locale.h])
42
43dnl Checks for typedefs, structures, and compiler characteristics.
44AC_HEADER_STDBOOL
45AC_C_CONST
46
47dnl Checks for library functions.
48AC_CHECK_FUNCS([setlocale sqrt])
49
50AC_CONFIG_FILES([
51Makefile
52po/Makefile.in
53m4/Makefile
54])
55
56AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.