COIN-OR::LEMON - Graph Library

source: lemon-0.x/configure.ac @ 2209:d3425607d41a

Last change on this file since 2209:d3425607d41a was 2108:f2c532541730, checked in by Akos Ladanyi, 13 years ago

Single makefile.

File size: 3.5 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2AC_PREREQ([2.59])
3AC_INIT([LEMON], [svn-head], [etik-ol@cs.elte.hu], [lemon])
4AC_CONFIG_AUX_DIR([build-aux])
5AC_CONFIG_MACRO_DIR([m4])
6AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
7AC_CONFIG_SRCDIR([lemon/list_graph.h])
8AC_CONFIG_HEADERS([config.h lemon/config.h])
9
10lx_cmdline_cxxflags_set=${CXXFLAGS+set}
11
12dnl Checks for programs.
13AC_PROG_CXX
14AC_PROG_CXXCPP
15AC_PROG_INSTALL
16AC_DISABLE_SHARED
17AC_PROG_LIBTOOL
18
19if test x"$lx_cmdline_cxxflags_set" != x"set" -a "$GXX" = yes; then
20  CXXFLAGS="$CXXFLAGS -Wall -W"
21fi
22
23AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
24
25dnl Checks for libraries.
26LX_CHECK_GLPK
27LX_CHECK_CPLEX
28
29dnl Enable/disable installing the documentation
30AC_ARG_ENABLE([doc],
31AS_HELP_STRING([--enable-doc@<:@=yes|no|full@:>@], [build the documentation (full enables internal documentation too) @<:@default=yes@:>@])
32AS_HELP_STRING([--disable-doc], [do not build the documentation]),
33              [], [enable_doc=yes])
34
35AC_MSG_CHECKING([whether to build the documention])
36case "$enable_doc" in
37  yes)
38    DOXYGEN_INTERNAL_DOCS=NO
39    AC_MSG_RESULT([yes])
40    ;;
41  full)
42    DOXYGEN_INTERNAL_DOCS=YES
43    AC_MSG_RESULT([full])
44    ;;
45  no)
46    DOXYGEN_INTERNAL_DOCS=NO
47    AC_MSG_RESULT([no])
48    ;;
49  *)
50    AC_MSG_ERROR([bad value $enable_doc for option --enable-doc])
51    ;;
52esac
53AC_SUBST(DOXYGEN_INTERNAL_DOCS)
54AM_CONDITIONAL([WANT_DOC], [test x"$enable_doc" != x"no"])
55
56dnl Disable/enable building the demo programs
57AC_ARG_ENABLE([demo],
58AS_HELP_STRING([--enable-demo], [build the demo programs])
59AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),
60              [], [enable_demo=no])
61AC_MSG_CHECKING([whether to build the demo programs])
62if test x"$enable_demo" != x"no"; then
63  AC_MSG_RESULT([yes])
64else
65  AC_MSG_RESULT([no])
66fi
67AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])
68
69dnl Disable/enable building the benchmarks
70AC_ARG_ENABLE([benchmark],
71AS_HELP_STRING([--enable-benchmark], [build the benchmarks])
72AS_HELP_STRING([--disable-benchmark], [do not build the benchmarks @<:@default@:>@]),
73              [], [enable_benchmark=no])
74AC_MSG_CHECKING([whether to build the benchmarks])
75if test x"$enable_benchmark" != x"no"; then
76  AC_MSG_RESULT([yes])
77else
78  AC_MSG_RESULT([no])
79fi
80AM_CONDITIONAL([WANT_BENCHMARK], [test x"$enable_benchmark" != x"no"])
81
82dnl Checks for header files.
83AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
84
85dnl Checks for typedefs, structures, and compiler characteristics.
86AC_C_CONST
87AC_C_INLINE
88AC_TYPE_SIZE_T
89AC_HEADER_TIME
90AC_STRUCT_TM
91
92dnl Checks for library functions.
93AC_HEADER_STDC
94AC_CHECK_FUNCS(gettimeofday times ctime_r)
95
96AC_CONFIG_FILES([
97Makefile
98lemon.spec
99autopackage/default.apspec
100doc/Doxyfile
101lemon/lemon.pc
102])
103
104AC_OUTPUT
105
106echo
107echo '****************************** SUMMARY ******************************'
108echo
109echo Package version............... : $PACKAGE-$VERSION
110echo
111echo C++ compiler.................. : $CXX
112echo C++ compiles flags............ : $CXXFLAGS
113echo
114echo GLPK support.................. : $lx_glpk_found
115echo CPLEX support................. : $lx_cplex_found
116echo
117echo build benchmarks.............. : $enable_benchmark
118echo build demo programs........... : $enable_demo
119echo
120echo The packace will be installed in
121echo -n '  '
122echo $prefix.
123echo
124echo The documentation will be installed in
125echo -n '  '
126eval echo ${datadir}/doc/$PACKAGE.
127echo
128echo '*********************************************************************'
129
130echo
131echo configure complete, now type \'make\' and then \'make install\'.
132echo
Note: See TracBrowser for help on using the repository browser.