COIN-OR::LEMON - Graph Library

source: lemon-0.x/configure.ac @ 1978:ef2d00e46897

Last change on this file since 1978:ef2d00e46897 was 1941:9fe177e0437d, checked in by Alpar Juttner, 14 years ago

The version tag of the trunk is svn-head

File size: 4.2 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2AC_INIT([LEMON], [svn-head], [etik-ol@cs.elte.hu], [lemon])
3AC_CONFIG_AUX_DIR([config])
4AM_INIT_AUTOMAKE([1.7])
5AC_CONFIG_SRCDIR([lemon/invalid.h])
6AC_CONFIG_HEADERS([config.h lemon/config.h])
7AC_PREREQ([2.59])
8
9lx_cmdline_cxxflags_set=${CXXFLAGS+set}
10
11dnl Checks for programs.
12AC_PROG_CXX
13AC_PROG_CXXCPP
14AC_PROG_INSTALL
15AC_DISABLE_SHARED
16AC_PROG_LIBTOOL
17
18if test x"$lx_cmdline_cxxflags_set" != x"set" -a "$GXX" = yes; then
19  CXXFLAGS="$CXXFLAGS -Wall -W"
20fi
21
22AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
23
24dnl Checks for libraries.
25LX_CHECK_GLPK
26LX_CHECK_CPLEX
27
28dnl Enable/disable installing the documentation
29AC_ARG_ENABLE([doc],
30AS_HELP_STRING([--enable-doc@<:@=yes|no|full@:>@], [build the documentation (full enables internal documentation too) @<:@default=yes@:>@])
31AS_HELP_STRING([--disable-doc], [do not build the documentation]),
32              [], [enable_doc=yes])
33
34AC_MSG_CHECKING([whether to build the documention])
35case "$enable_doc" in
36  yes)
37    DOXYGEN_INTERNAL_DOCS=NO
38    AC_MSG_RESULT([yes])
39    ;;
40  full)
41    DOXYGEN_INTERNAL_DOCS=YES
42    AC_MSG_RESULT([full])
43    ;;
44  no)
45    DOXYGEN_INTERNAL_DOCS=NO
46    AC_MSG_RESULT([no])
47    ;;
48  *)
49    AC_MSG_ERROR([bad value $enable_doc for option --enable-doc])
50    ;;
51esac
52AC_SUBST(DOXYGEN_INTERNAL_DOCS)
53AM_CONDITIONAL([WANT_DOC], [test x"$enable_doc" != x"no"])
54
55dnl Disable/enable building the GUI
56AC_ARG_ENABLE([gui],
57AS_HELP_STRING([--enable-gui], [build the GUI])
58AS_HELP_STRING([--disable-gui], [do not build the GUI @<:@default@:>@]),
59              [], [enable_gui=no])
60AC_MSG_CHECKING([whether to build the GUI])
61if test x"$enable_gui" != x"no"; then
62  AC_MSG_RESULT([yes])
63else
64  AC_MSG_RESULT([no])
65fi
66if test x"$enable_gui" != x"no"; then
67  PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0])
68fi
69AM_CONDITIONAL([WANT_GUI], [test x"$enable_gui" != x"no"])
70
71dnl Disable/enable building the demo programs
72AC_ARG_ENABLE([demo],
73AS_HELP_STRING([--enable-demo], [build the demo programs])
74AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),
75              [], [enable_demo=no])
76AC_MSG_CHECKING([whether to build the demo programs])
77if test x"$enable_demo" != x"no"; then
78  AC_MSG_RESULT([yes])
79else
80  AC_MSG_RESULT([no])
81fi
82AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])
83
84dnl Disable/enable building the benchmarks
85AC_ARG_ENABLE([benchmark],
86AS_HELP_STRING([--enable-benchmark], [build the benchmarks])
87AS_HELP_STRING([--disable-benchmark], [do not build the benchmarks @<:@default@:>@]),
88              [], [enable_benchmark=no])
89AC_MSG_CHECKING([whether to build the benchmarks])
90if test x"$enable_benchmark" != x"no"; then
91  AC_MSG_RESULT([yes])
92else
93  AC_MSG_RESULT([no])
94fi
95AM_CONDITIONAL([WANT_BENCHMARK], [test x"$enable_benchmark" != x"no"])
96
97dnl Checks for header files.
98AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
99
100dnl Checks for header files.
101AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
102
103dnl Checks for typedefs, structures, and compiler characteristics.
104AC_C_CONST
105AC_C_INLINE
106AC_TYPE_SIZE_T
107AC_HEADER_TIME
108AC_STRUCT_TM
109
110dnl Checks for library functions.
111AC_HEADER_STDC
112AC_CHECK_FUNCS(gettimeofday times ctime_r)
113
114AC_CONFIG_FILES([
115Makefile
116lemon.spec
117autopackage/default.apspec
118doc/Makefile
119doc/Doxyfile
120lemon/Makefile
121lemon/lemon.pc
122benchmark/Makefile
123demo/Makefile
124test/Makefile
125gui/Makefile
126])
127
128AC_OUTPUT
129
130echo
131echo '****************************** SUMMARY ******************************'
132echo
133echo Package version............... : $PACKAGE-$VERSION
134echo
135echo C++ compiler.................. : $CXX
136echo C++ compiles flags............ : $CXXFLAGS
137echo
138echo GLPK support.................. : $lx_glpk_found
139echo CPLEX support................. : $lx_cplex_found
140echo
141echo build benchmarks.............. : $enable_benchmark
142echo build demo programs........... : $enable_demo
143echo build GUI..................... : $enable_gui
144echo
145echo The packace will be installed in
146echo -n '  '
147echo $prefix.
148echo
149echo The documentation will be installed in
150echo -n '  '
151eval echo ${datadir}/doc/$PACKAGE.
152echo
153echo '*********************************************************************'
154
155echo
156echo configure complete, now type \'make\' and then \'make install\'.
157echo
Note: See TracBrowser for help on using the repository browser.