COIN-OR::LEMON - Graph Library

source: lemon/configure.ac @ 144:4e626dbbe408

Last change on this file since 144:4e626dbbe408 was 91:e28fc773f3c0, checked in by Alpar Juttner <alpar@…>, 16 years ago

Update the contact e-mail address

File size: 4.1 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([lemon_version_major], [0])
5m4_define([lemon_version_minor], [99])
6m4_define([lemon_version_micro], [])
7m4_define([lemon_version_nano], [])
8m4_define([lemon_version_tag], [hg])
9m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
10m4_define([lemon_version], [lemon_version_major().lemon_version_minor()ifelse(lemon_version_micro(), [], [], [.lemon_version_micro()])ifelse(lemon_version_nano(), [], [], [.lemon_version_nano()])ifelse(lemon_version_tag(), [], [], lemon_version_tag(), [hg], [[_]lemon_version_tag()[_]lemon_hg_revision()], [[_]lemon_version_tag()])])
11
12AC_PREREQ([2.59])
13AC_INIT([LEMON], [lemon_version()], [lemon-devel@lemon.cs.elte.hu], [lemon])
14AC_CONFIG_AUX_DIR([build-aux])
15AC_CONFIG_MACRO_DIR([m4])
16AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])
17AC_CONFIG_SRCDIR([lemon/list_graph.h])
18AC_CONFIG_HEADERS([config.h lemon/config.h])
19
20lx_cmdline_cxxflags_set=${CXXFLAGS+set}
21
22dnl Checks for programs.
23AC_PROG_CXX
24AC_PROG_CXXCPP
25AC_PROG_INSTALL
26AC_DISABLE_SHARED
27AC_PROG_LIBTOOL
28
29AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
30
31if test x"$lx_cmdline_cxxflags_set" != x"set" -a "$GXX" = yes; then
32  CXXFLAGS="$CXXFLAGS -Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"
33fi
34
35dnl Checks for libraries.
36LX_CHECK_GLPK
37LX_CHECK_CPLEX
38LX_CHECK_SOPLEX
39
40dnl Disable/enable building the demo programs
41AC_ARG_ENABLE([demo],
42AS_HELP_STRING([--enable-demo], [build the demo programs])
43AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),
44              [], [enable_demo=no])
45AC_MSG_CHECKING([whether to build the demo programs])
46if test x"$enable_demo" != x"no"; then
47  AC_MSG_RESULT([yes])
48else
49  AC_MSG_RESULT([no])
50fi
51AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])
52
53dnl Disable/enable building the binary tools
54AC_ARG_ENABLE([tools],
55AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])
56AS_HELP_STRING([--disable-tools], [do not build additional tools]),
57              [], [enable_tools=yes])
58AC_MSG_CHECKING([whether to build the additional tools])
59if test x"$enable_tools" != x"no"; then
60  AC_MSG_RESULT([yes])
61else
62  AC_MSG_RESULT([no])
63fi
64AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])
65
66dnl Disable/enable building the benchmarks
67AC_ARG_ENABLE([benchmark],
68AS_HELP_STRING([--enable-benchmark], [build the benchmarks])
69AS_HELP_STRING([--disable-benchmark], [do not build the benchmarks @<:@default@:>@]),
70              [], [enable_benchmark=no])
71AC_MSG_CHECKING([whether to build the benchmarks])
72if test x"$enable_benchmark" != x"no"; then
73  AC_MSG_RESULT([yes])
74else
75  AC_MSG_RESULT([no])
76fi
77AM_CONDITIONAL([WANT_BENCHMARK], [test x"$enable_benchmark" != x"no"])
78
79dnl Checks for header files.
80AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
81
82dnl Checks for typedefs, structures, and compiler characteristics.
83AC_C_CONST
84AC_C_INLINE
85AC_TYPE_SIZE_T
86AC_HEADER_TIME
87AC_STRUCT_TM
88
89dnl Checks for library functions.
90AC_HEADER_STDC
91AC_CHECK_FUNCS(gettimeofday times ctime_r)
92
93AC_CONFIG_FILES([
94Makefile
95doc/Doxyfile
96lemon/lemon.pc
97])
98
99AC_OUTPUT
100
101echo
102echo '****************************** SUMMARY ******************************'
103echo
104echo Package version............... : $PACKAGE-$VERSION
105echo
106echo C++ compiler.................. : $CXX
107echo C++ compiles flags............ : $CXXFLAGS
108echo
109echo GLPK support.................. : $lx_glpk_found
110echo CPLEX support................. : $lx_cplex_found
111echo SOPLEX support................ : $lx_soplex_found
112echo
113echo Build benchmarks.............. : $enable_benchmark
114echo Build demo programs........... : $enable_demo
115echo Build additional tools........ : $enable_tools
116echo
117echo The packace will be installed in
118echo -n '  '
119echo $prefix.
120echo
121echo '*********************************************************************'
122
123echo
124echo Configure complete, now type \'make\' and then \'make install\'.
125echo
Note: See TracBrowser for help on using the repository browser.