COIN-OR::LEMON - Graph Library

source: lemon/configure.ac @ 219:b9c6a47c977b

Last change on this file since 219:b9c6a47c977b was 219:b9c6a47c977b, checked in by Alpar Juttner <alpar@…>, 11 years ago

Turn off treeview in the doc.

make now recognises if Doxygen.in has updated. (Thanks to Akos)

File size: 4.0 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([lemon_version_number], [])
5m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
6m4_define([lemon_version], [ifelse(lemon_version_number(), [], [lemon_hg_revision()], [lemon_version_number()])])
7
8AC_PREREQ([2.59])
9AC_INIT([LEMON], [lemon_version()], [lemon-devel@lemon.cs.elte.hu], [lemon])
10AC_CONFIG_AUX_DIR([build-aux])
11AC_CONFIG_MACRO_DIR([m4])
12AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])
13AC_CONFIG_SRCDIR([lemon/list_graph.h])
14AC_CONFIG_HEADERS([config.h lemon/config.h])
15
16lx_cmdline_cxxflags_set=${CXXFLAGS+set}
17
18dnl Checks for programs.
19AC_PROG_CXX
20AC_PROG_CXXCPP
21AC_PROG_INSTALL
22AC_DISABLE_SHARED
23AC_PROG_LIBTOOL
24
25AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
26AC_CHECK_PROG([gs_found],[gs],[yes],[no])
27
28if test x"$lx_cmdline_cxxflags_set" != x"set" -a "$GXX" = yes; then
29  CXXFLAGS="$CXXFLAGS -Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"
30fi
31
32dnl Checks for libraries.
33LX_CHECK_GLPK
34LX_CHECK_CPLEX
35LX_CHECK_SOPLEX
36
37dnl Disable/enable building the demo programs
38AC_ARG_ENABLE([demo],
39AS_HELP_STRING([--enable-demo], [build the demo programs])
40AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),
41              [], [enable_demo=no])
42AC_MSG_CHECKING([whether to build the demo programs])
43if test x"$enable_demo" != x"no"; then
44  AC_MSG_RESULT([yes])
45else
46  AC_MSG_RESULT([no])
47fi
48AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])
49
50dnl Disable/enable building the binary tools
51AC_ARG_ENABLE([tools],
52AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])
53AS_HELP_STRING([--disable-tools], [do not build additional tools]),
54              [], [enable_tools=yes])
55AC_MSG_CHECKING([whether to build the additional tools])
56if test x"$enable_tools" != x"no"; then
57  AC_MSG_RESULT([yes])
58else
59  AC_MSG_RESULT([no])
60fi
61AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])
62
63dnl Disable/enable building the benchmarks
64AC_ARG_ENABLE([benchmark],
65AS_HELP_STRING([--enable-benchmark], [build the benchmarks])
66AS_HELP_STRING([--disable-benchmark], [do not build the benchmarks @<:@default@:>@]),
67              [], [enable_benchmark=no])
68AC_MSG_CHECKING([whether to build the benchmarks])
69if test x"$enable_benchmark" != x"no"; then
70  AC_MSG_RESULT([yes])
71else
72  AC_MSG_RESULT([no])
73fi
74AM_CONDITIONAL([WANT_BENCHMARK], [test x"$enable_benchmark" != x"no"])
75
76dnl Checks for header files.
77AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
78
79dnl Checks for typedefs, structures, and compiler characteristics.
80AC_C_CONST
81AC_C_INLINE
82AC_TYPE_SIZE_T
83AC_HEADER_TIME
84AC_STRUCT_TM
85
86dnl Checks for library functions.
87AC_HEADER_STDC
88AC_CHECK_FUNCS(gettimeofday times ctime_r)
89
90dnl Add dependencies on files generated by configure.
91AC_SUBST([CONFIG_STATUS_DEPENDENCIES],
92  ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in'])
93
94AC_CONFIG_FILES([
95Makefile
96doc/Doxyfile
97lemon/lemon.pc
98])
99
100AC_OUTPUT
101
102echo
103echo '****************************** SUMMARY ******************************'
104echo
105echo Package version............... : $PACKAGE-$VERSION
106echo
107echo C++ compiler.................. : $CXX
108echo C++ compiles flags............ : $CXXFLAGS
109echo
110echo GLPK support.................. : $lx_glpk_found
111echo CPLEX support................. : $lx_cplex_found
112echo SOPLEX support................ : $lx_soplex_found
113echo
114echo Build benchmarks.............. : $enable_benchmark
115echo Build demo programs........... : $enable_demo
116echo Build additional tools........ : $enable_tools
117echo
118echo The packace will be installed in
119echo -n '  '
120echo $prefix.
121echo
122echo '*********************************************************************'
123
124echo
125echo Configure complete, now type \'make\' and then \'make install\'.
126echo
Note: See TracBrowser for help on using the repository browser.