lemon-0.x: config/lx_check_glpk.m4@a6f019fa6e7a

     1 AC_DEFUN([LX_CHECK_GLPK],

2 [

     3   AC_ARG_WITH([glpk],

     4 AS_HELP_STRING([--with-glpk@<:@=PREFIX@:>@], [search for GLPK under PREFIX or under the default search paths if PREFIX is not given @<:@default@:>@])

     5 AS_HELP_STRING([--without-glpk], [disable checking for GLPK]),

     6               [], [with_glpk=yes])

     8   AC_ARG_WITH([glpk-includedir],

     9 AS_HELP_STRING([--with-glpk-includedir=DIR], [search for GLPK headers in DIR]),

    10               [], [with_glpk_includedir=no])

    12   AC_ARG_WITH([glpk-libdir],

    13 AS_HELP_STRING([--with-glpk-libdir=DIR], [search for GLPK libraries in DIR]),

    14               [], [with_glpk_libdir=no])

    16   lx_glpk_found=no

    17   if test x"$with_glpk" != x"no"; then

    18     AC_MSG_CHECKING([for GLPK])

    20     if test x"$with_glpk_includedir" != x"no"; then

    21       GLPK_CFLAGS="-I$with_glpk_includedir"

    22     elif test x"$with_glpk" != x"yes"; then

    23       GLPK_CFLAGS="-I$with_glpk/include"

    24     fi

    26     if test x"$with_glpk_libdir" != x"no"; then

    27       GLPK_LDFLAGS="-L$with_glpk_libdir"

    28     elif test x"$with_glpk" != x"yes"; then

    29       GLPK_LDFLAGS="-L$with_glpk/lib"

    30     fi

    31     GLPK_LIBS="-lglpk"

    33     lx_save_cxxflags="$CXXFLAGS"

    34     lx_save_ldflags="$LDFLAGS"

    35     lx_save_libs="$LIBS"

    36     CXXFLAGS="$GLPK_CFLAGS"

    37     LDFLAGS="$GLPK_LDFLAGS"

    38     LIBS="$GLPK_LIBS"

    40     lx_glpk_test_prog='

    41       extern "C" {

    42       #include <glpk.h>

    43       }

    45       int main(int argc, char* argv[])

    46       {

    47         LPX *lp;

    48         lp = lpx_create_prob();

    49         lpx_delete_prob(lp);

    50         return 0;

    51       }'

    53     AC_LANG_PUSH(C++)

    54     AC_LINK_IFELSE([$lx_glpk_test_prog], [lx_glpk_found=yes], [lx_glpk_found=no])

    55     AC_LANG_POP(C++)

    57     CXXFLAGS="$lx_save_cxxflags"

    58     LDFLAGS="$lx_save_ldflags"

    59     LIBS="$lx_save_libs"

    61     if test x"$lx_glpk_found" = x"yes"; then

    62       AC_DEFINE([HAVE_GLPK], [1], [Define to 1 if you have GLPK.])

    63       AC_MSG_RESULT([yes])

    64     else

    65       GLPK_CFLAGS=""

    66       GLPK_LDFLAGS=""

    67       GLPK_LIBS=""

    68       AC_MSG_RESULT([no])

    69     fi

    70   fi

    71   GLPK_LIBS="$GLPK_LDFLAGS $GLPK_LIBS"

    72   AC_SUBST(GLPK_CFLAGS)

    73   AC_SUBST(GLPK_LIBS)

    74   AM_CONDITIONAL([HAVE_GLPK], [test x"$lx_glpk_found" = x"yes"])

    75 ])

author	alpar
	Thu, 17 Nov 2005 10:16:29 +0000
changeset 1812	a6f019fa6e7a
permissions	-rw-r--r--