configure.ac
author Akos Ladanyi <ladanyi@tmit.bme.hu>
Wed, 27 May 2009 13:08:47 +0100
changeset 721 0cd6d84103a4
parent 615 b53a9068e3e4
parent 540 8a144437db7d
child 725 d1e1cd94bf49
permissions -rw-r--r--
Add tools/CMakeLists.txt to the tarball
     1 dnl Process this file with autoconf to produce a configure script.
     2 
     3 dnl Version information.
     4 m4_define([lemon_version_number],
     5 	[m4_normalize(esyscmd([echo ${LEMON_VERSION}]))])
     6 dnl m4_define([lemon_version_number], [])
     7 m4_define([lemon_hg_path], [m4_normalize(esyscmd([./scripts/chg-len.py]))])
     8 m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
     9 m4_define([lemon_version], [ifelse(lemon_version_number(),
    10 			   [],
    11 			   [lemon_hg_path().lemon_hg_revision()],
    12 			   [lemon_version_number()])])
    13 
    14 AC_PREREQ([2.59])
    15 AC_INIT([LEMON], [lemon_version()], [lemon-user@lemon.cs.elte.hu], [lemon])
    16 AC_CONFIG_AUX_DIR([build-aux])
    17 AC_CONFIG_MACRO_DIR([m4])
    18 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])
    19 AC_CONFIG_SRCDIR([lemon/list_graph.h])
    20 AC_CONFIG_HEADERS([config.h lemon/config.h])
    21 
    22 dnl Do compilation tests using the C++ compiler.
    23 AC_LANG([C++])
    24 
    25 dnl Check the existence of long long type.
    26 AC_CHECK_TYPE(long long, [long_long_found=yes], [long_long_found=no])
    27 if test x"$long_long_found" = x"yes"; then
    28   AC_DEFINE([LEMON_HAVE_LONG_LONG], [1], [Define to 1 if you have long long.])
    29 fi
    30 
    31 dnl Checks for programs.
    32 AC_PROG_CXX
    33 AC_PROG_CXXCPP
    34 AC_PROG_INSTALL
    35 AC_DISABLE_SHARED
    36 AC_PROG_LIBTOOL
    37 
    38 AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
    39 AC_CHECK_PROG([gs_found],[gs],[yes],[no])
    40 
    41 dnl Detect Intel compiler.
    42 AC_MSG_CHECKING([whether we are using the Intel C++ compiler])
    43 AC_COMPILE_IFELSE([#ifndef __INTEL_COMPILER
    44 choke me
    45 #endif], [ICC=[yes]], [ICC=[no]])
    46 if test x"$ICC" = x"yes"; then
    47   AC_MSG_RESULT([yes])
    48 else
    49   AC_MSG_RESULT([no])
    50 fi
    51 
    52 dnl Set custom compiler flags when using g++.
    53 if test "$GXX" = yes -a "$ICC" = no; then
    54   WARNINGCXXFLAGS="-Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"
    55 fi
    56 AC_SUBST([WARNINGCXXFLAGS])
    57 
    58 dnl Checks for libraries.
    59 LX_CHECK_GLPK
    60 LX_CHECK_CPLEX
    61 LX_CHECK_SOPLEX
    62 LX_CHECK_COIN
    63 
    64 AM_CONDITIONAL([HAVE_LP], [test x"$lx_lp_found" = x"yes"])
    65 AM_CONDITIONAL([HAVE_MIP], [test x"$lx_mip_found" = x"yes"])
    66 
    67 dnl Disable/enable building the binary tools.
    68 AC_ARG_ENABLE([tools],
    69 AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])
    70 AS_HELP_STRING([--disable-tools], [do not build additional tools]),
    71               [], [enable_tools=yes])
    72 AC_MSG_CHECKING([whether to build the additional tools])
    73 if test x"$enable_tools" != x"no"; then
    74   AC_MSG_RESULT([yes])
    75 else
    76   AC_MSG_RESULT([no])
    77 fi
    78 AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])
    79 
    80 dnl Checks for header files.
    81 AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
    82 
    83 dnl Checks for typedefs, structures, and compiler characteristics.
    84 AC_C_CONST
    85 AC_C_INLINE
    86 AC_TYPE_SIZE_T
    87 AC_HEADER_TIME
    88 AC_STRUCT_TM
    89 
    90 dnl Checks for library functions.
    91 AC_HEADER_STDC
    92 AC_CHECK_FUNCS(gettimeofday times ctime_r)
    93 
    94 dnl Add dependencies on files generated by configure.
    95 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],
    96   ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in $(top_srcdir)/cmake/version.cmake.in'])
    97 
    98 AC_CONFIG_FILES([
    99 Makefile
   100 demo/Makefile
   101 cmake/version.cmake
   102 doc/Doxyfile
   103 lemon/lemon.pc
   104 ])
   105 
   106 AC_OUTPUT
   107 
   108 echo
   109 echo '****************************** SUMMARY ******************************'
   110 echo
   111 echo Package version............... : $PACKAGE-$VERSION
   112 echo
   113 echo C++ compiler.................. : $CXX
   114 echo C++ compiles flags............ : $WARNINGCXXFLAGS $CXXFLAGS
   115 echo
   116 echo Compiler supports long long... : $long_long_found
   117 echo
   118 echo GLPK support.................. : $lx_glpk_found
   119 echo CPLEX support................. : $lx_cplex_found
   120 echo SOPLEX support................ : $lx_soplex_found
   121 echo CLP support................... : $lx_clp_found
   122 echo CBC support................... : $lx_cbc_found
   123 echo
   124 echo Build additional tools........ : $enable_tools
   125 echo
   126 echo The packace will be installed in
   127 echo -n '  '
   128 echo $prefix.
   129 echo
   130 echo '*********************************************************************'
   131 
   132 echo
   133 echo Configure complete, now type \'make\' and then \'make install\'.
   134 echo