RhodeCode

ACLOCAL_AMFLAGS = -I m4

AM_CPPFLAGS = -I$(top_srcdir) -I$(top_builddir)

LDADD = $(top_builddir)/lemon/libemon.la

EXTRA_DIST = \

	LICENSE \

	m4/lx_check_cplex.m4 \

	m4/lx_check_glpk.m4 \

	m4/lx_check_soplex.m4 \

	CMakeLists.txt \

	cmake

pkgconfigdir = $(libdir)/pkgconfig

lemondir = $(pkgincludedir)

bitsdir = $(lemondir)/bits

conceptdir = $(lemondir)/concepts

pkgconfig_DATA =

lib_LTLIBRARIES =

lemon_HEADERS =

bits_HEADERS =

concept_HEADERS =

noinst_HEADERS =

noinst_PROGRAMS =

bin_PROGRAMS =

check_PROGRAMS =

TESTS =

XFAIL_TESTS =

include lemon/Makefile.am

include test/Makefile.am

include doc/Makefile.am

include demo/Makefile.am

include tools/Makefile.am

MRPROPERFILES = \

	aclocal.m4 \

	config.h.in \

	config.h.in~ \

	configure \

	Makefile.in \

	build-aux/config.guess \

	build-aux/config.sub \

	build-aux/depcomp \

	build-aux/install-sh \

	build-aux/ltmain.sh \

	build-aux/missing \

	doc/doxygen.log

mrproper:

	$(MAKE) $(AM_MAKEFLAGS) maintainer-clean

	-rm -f $(MRPROPERFILES)

dist-bz2: dist

	zcat $(PACKAGE)-$(VERSION).tar.gz | \

	bzip2 --best -c > $(PACKAGE)-$(VERSION).tar.bz2

distcheck-bz2: distcheck

	zcat $(PACKAGE)-$(VERSION).tar.gz | \

	bzip2 --best -c > $(PACKAGE)-$(VERSION).tar.bz2

.PHONY: mrproper dist-bz2 distcheck-bz2

==================================================================

LEMON - a Library of Efficient Models and Optimization in Networks

==================================================================

LEMON is an open source library written in C++. It provides

easy-to-use implementations of common data structures and algorithms

in the area of optimization and helps implementing new ones. The main

focus is on graphs and graph algorithms, thus it is especially

suitable for solving design and optimization problems of

telecommunication networks. To achieve wide usability its data

structures and algorithms provide generic interfaces.

Contents

========

LICENSE

   Copying, distribution and modification conditions and terms.

INSTALL

   General building and installation instructions.

lemon/

   Source code of LEMON library.

doc/

   Documentation of LEMON. The starting page is doc/html/index.html.

demo/

   Some example programs to make you easier to get familiar with LEMON.

test/

   Contains programs to check the integrity and correctness of LEMON.

tools/

   Various utilities related to LEMON.

dnl Process this file with autoconf to produce a configure script.

dnl Version information.

m4_define([lemon_version_number],

	[m4_normalize(esyscmd([echo ${LEMON_VERSION}]))])

dnl m4_define([lemon_version_number], [])

m4_define([lemon_hg_path], [m4_normalize(esyscmd([./scripts/chg-len.py]))])

m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])

m4_define([lemon_version], [ifelse(lemon_version_number(),

			   [],

			   [lemon_hg_path().lemon_hg_revision()],

			   [lemon_version_number()])])

AC_PREREQ([2.59])

AC_INIT([LEMON], [lemon_version()], [lemon-user@lemon.cs.elte.hu], [lemon])

AC_CONFIG_AUX_DIR([build-aux])

AC_CONFIG_MACRO_DIR([m4])

AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])

AC_CONFIG_SRCDIR([lemon/list_graph.h])

AC_CONFIG_HEADERS([config.h lemon/config.h])

lx_cmdline_cxxflags_set=${CXXFLAGS+set}

dnl Do compilation tests using the C++ compiler.

AC_LANG([C++])

dnl Checks for programs.

AC_PROG_CXX

AC_PROG_CXXCPP

AC_PROG_INSTALL

AC_DISABLE_SHARED

AC_PROG_LIBTOOL

AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])

AC_CHECK_PROG([gs_found],[gs],[yes],[no])

dnl Detect Intel compiler.

AC_MSG_CHECKING([whether we are using the Intel C++ compiler])

AC_COMPILE_IFELSE([#ifndef __INTEL_COMPILER

choke me

#endif], [ICC=[yes]], [ICC=[no]])

if test x"$ICC" = x"yes"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

dnl Set custom compiler flags when using g++.

if test x"$lx_cmdline_cxxflags_set" != x"set" -a "$GXX" = yes -a "$ICC" = no; then

  CXXFLAGS="$CXXFLAGS -Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"

fi

dnl Checks for libraries.

#LX_CHECK_GLPK

#LX_CHECK_CPLEX

#LX_CHECK_SOPLEX

dnl Disable/enable building the demo programs.

AC_ARG_ENABLE([demo],

AS_HELP_STRING([--enable-demo], [build the demo programs])

AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),

              [], [enable_demo=no])

AC_MSG_CHECKING([whether to build the demo programs])

if test x"$enable_demo" != x"no"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])

dnl Disable/enable building the binary tools.

AC_ARG_ENABLE([tools],

AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])

AS_HELP_STRING([--disable-tools], [do not build additional tools]),

              [], [enable_tools=yes])

AC_MSG_CHECKING([whether to build the additional tools])

if test x"$enable_tools" != x"no"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])

dnl Checks for header files.

AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.

AC_C_CONST

AC_C_INLINE

AC_TYPE_SIZE_T

AC_HEADER_TIME

AC_STRUCT_TM

dnl Checks for library functions.

AC_HEADER_STDC

AC_CHECK_FUNCS(gettimeofday times ctime_r)

dnl Add dependencies on files generated by configure.

AC_SUBST([CONFIG_STATUS_DEPENDENCIES],

  ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in'])

AC_CONFIG_FILES([

Makefile

doc/Doxyfile

lemon/lemon.pc

])

AC_OUTPUT

echo

echo '****************************** SUMMARY ******************************'

echo

echo Package version............... : $PACKAGE-$VERSION

echo

echo C++ compiler.................. : $CXX

echo C++ compiles flags............ : $CXXFLAGS

echo

#echo GLPK support.................. : $lx_glpk_found

#echo CPLEX support................. : $lx_cplex_found

#echo SOPLEX support................ : $lx_soplex_found

#echo

echo Build demo programs........... : $enable_demo

echo Build additional tools........ : $enable_tools

echo

echo The packace will be installed in

echo -n '  '

echo $prefix.

echo

echo '*********************************************************************'

echo

echo Configure complete, now type \'make\' and then \'make install\'.

echo

if WANT_TOOLS

bin_PROGRAMS +=

endif WANT_TOOLS