RhodeCode

dnl Process this file with autoconf to produce a configure script.

dnl Version information.

m4_define([lemon_version_number],

	[m4_normalize(esyscmd([echo ${LEMON_VERSION}]))])

dnl m4_define([lemon_version_number], [])

m4_define([lemon_hg_path], [m4_normalize(esyscmd([./scripts/chg-len.py]))])

m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])

m4_define([lemon_version], [ifelse(lemon_version_number(),

			   [],

			   [lemon_hg_path().lemon_hg_revision()],

			   [lemon_version_number()])])

AC_PREREQ([2.59])

AC_INIT([LEMON], [lemon_version()], [lemon-user@lemon.cs.elte.hu], [lemon])

AC_CONFIG_AUX_DIR([build-aux])

AC_CONFIG_MACRO_DIR([m4])

AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])

AC_CONFIG_SRCDIR([lemon/list_graph.h])

AC_CONFIG_HEADERS([config.h lemon/config.h])

dnl Do compilation tests using the C++ compiler.

AC_LANG([C++])

dnl Checks for programs.

AC_PROG_CXX

AC_PROG_CXXCPP

AC_PROG_INSTALL

AC_DISABLE_SHARED

AC_PROG_LIBTOOL

AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])

AC_CHECK_PROG([gs_found],[gs],[yes],[no])

dnl Detect Intel compiler.

AC_MSG_CHECKING([whether we are using the Intel C++ compiler])

AC_COMPILE_IFELSE([#ifndef __INTEL_COMPILER

choke me

#endif], [ICC=[yes]], [ICC=[no]])

if test x"$ICC" = x"yes"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

dnl Set custom compiler flags when using g++.

if test "$GXX" = yes -a "$ICC" = no; then

  WARNINGCXXFLAGS="-Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"

fi

AC_SUBST([WARNINGCXXFLAGS])

dnl Checks for libraries.

#LX_CHECK_GLPK

#LX_CHECK_CPLEX

#LX_CHECK_SOPLEX

dnl Disable/enable building the demo programs.

AC_ARG_ENABLE([demo],

AS_HELP_STRING([--enable-demo], [build the demo programs])

AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),

              [], [enable_demo=no])

AC_MSG_CHECKING([whether to build the demo programs])

if test x"$enable_demo" != x"no"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])

dnl Disable/enable building the binary tools.

AC_ARG_ENABLE([tools],

AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])

AS_HELP_STRING([--disable-tools], [do not build additional tools]),

              [], [enable_tools=yes])

AC_MSG_CHECKING([whether to build the additional tools])

if test x"$enable_tools" != x"no"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])

dnl Checks for header files.

AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.

AC_C_CONST

AC_C_INLINE

AC_TYPE_SIZE_T

AC_HEADER_TIME

AC_STRUCT_TM

dnl Checks for library functions.

AC_HEADER_STDC

AC_CHECK_FUNCS(gettimeofday times ctime_r)

dnl Add dependencies on files generated by configure.

AC_SUBST([CONFIG_STATUS_DEPENDENCIES],

  ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in'])

AC_CONFIG_FILES([

Makefile

doc/Doxyfile

lemon/lemon.pc

])

AC_OUTPUT

echo

echo '****************************** SUMMARY ******************************'

echo

echo Package version............... : $PACKAGE-$VERSION

echo

echo C++ compiler.................. : $CXX

echo C++ compiles flags............ : $WARNINGCXXFLAGS $CXXFLAGS

echo

#echo GLPK support.................. : $lx_glpk_found

#echo CPLEX support................. : $lx_cplex_found

#echo SOPLEX support................ : $lx_soplex_found

#echo

echo Build demo programs........... : $enable_demo

echo Build additional tools........ : $enable_tools

echo

echo The packace will be installed in

echo -n '  '

echo $prefix.

echo

echo '*********************************************************************'

echo

echo Configure complete, now type \'make\' and then \'make install\'.

echo

/* Define to 1 if you have CPLEX. */

#undef HAVE_CPLEX

/* Define to 1 if you have GLPK. */

#undef HAVE_GLPK

AC_DEFUN([LX_CHECK_CPLEX],

[

  AC_ARG_WITH([cplex],

AS_HELP_STRING([--with-cplex@<:@=PREFIX@:>@], [search for CPLEX under PREFIX or under the default search paths if PREFIX is not given @<:@default@:>@])

AS_HELP_STRING([--without-cplex], [disable checking for CPLEX]),

              [], [with_cplex=yes])

  AC_ARG_WITH([cplex-includedir],

AS_HELP_STRING([--with-cplex-includedir=DIR], [search for CPLEX headers in DIR]),

              [], [with_cplex_includedir=no])

  AC_ARG_WITH([cplex-libdir],

AS_HELP_STRING([--with-cplex-libdir=DIR], [search for CPLEX libraries in DIR]),

              [], [with_cplex_libdir=no])

  lx_cplex_found=no

  if test x"$with_cplex" != x"no"; then

    AC_MSG_CHECKING([for CPLEX])

    if test x"$with_cplex_includedir" != x"no"; then

      CPLEX_CFLAGS="-I$with_cplex_includedir"

    elif test x"$with_cplex" != x"yes"; then

      CPLEX_CFLAGS="-I$with_cplex/include"

    elif test x"$CPLEX_INCLUDEDIR" != x; then

      CPLEX_CFLAGS="-I$CPLEX_INCLUDEDIR"

    fi

    if test x"$with_cplex_libdir" != x"no"; then

      CPLEX_LDFLAGS="-L$with_cplex_libdir"

    elif test x"$with_cplex" != x"yes"; then

      CPLEX_LDFLAGS="-L$with_cplex/lib"

    elif test x"$CPLEX_LIBDIR" != x; then

      CPLEX_LDFLAGS="-L$CPLEX_LIBDIR"

    fi

    CPLEX_LIBS="-lcplex -lm -lpthread"

    lx_save_cxxflags="$CXXFLAGS"

    lx_save_ldflags="$LDFLAGS"

    lx_save_libs="$LIBS"

    CXXFLAGS="$CPLEX_CFLAGS"

    LDFLAGS="$CPLEX_LDFLAGS"

    LIBS="$CPLEX_LIBS"

    lx_cplex_test_prog='

      extern "C" {

      #include <ilcplex/cplex.h>

      }

      int main(int argc, char** argv)

      {

        CPXENVptr env = NULL;

        return 0;

      }'

    AC_LANG_PUSH(C++)

    AC_LINK_IFELSE([$lx_cplex_test_prog], [lx_cplex_found=yes], [lx_cplex_found=no])

    AC_LANG_POP(C++)

    CXXFLAGS="$lx_save_cxxflags"

    LDFLAGS="$lx_save_ldflags"

    LIBS="$lx_save_libs"

    if test x"$lx_cplex_found" = x"yes"; then

      AC_DEFINE([HAVE_CPLEX], [1], [Define to 1 if you have CPLEX.])

      AC_MSG_RESULT([yes])

    else

      CPLEX_CFLAGS=""

      CPLEX_LDFLAGS=""

      CPLEX_LIBS=""

      AC_MSG_RESULT([no])

    fi

  fi

  CPLEX_LIBS="$CPLEX_LDFLAGS $CPLEX_LIBS"

  AC_SUBST(CPLEX_CFLAGS)

  AC_SUBST(CPLEX_LIBS)

  AM_CONDITIONAL([HAVE_CPLEX], [test x"$lx_cplex_found" = x"yes"])

])

AC_DEFUN([LX_CHECK_GLPK],

[

  AC_ARG_WITH([glpk],

AS_HELP_STRING([--with-glpk@<:@=PREFIX@:>@], [search for GLPK under PREFIX or under the default search paths if PREFIX is not given @<:@default@:>@])

AS_HELP_STRING([--without-glpk], [disable checking for GLPK]),

              [], [with_glpk=yes])

  AC_ARG_WITH([glpk-includedir],

AS_HELP_STRING([--with-glpk-includedir=DIR], [search for GLPK headers in DIR]),

              [], [with_glpk_includedir=no])

  AC_ARG_WITH([glpk-libdir],

AS_HELP_STRING([--with-glpk-libdir=DIR], [search for GLPK libraries in DIR]),

              [], [with_glpk_libdir=no])

  lx_glpk_found=no

  if test x"$with_glpk" != x"no"; then

    AC_MSG_CHECKING([for GLPK])

    if test x"$with_glpk_includedir" != x"no"; then

      GLPK_CFLAGS="-I$with_glpk_includedir"

    elif test x"$with_glpk" != x"yes"; then

      GLPK_CFLAGS="-I$with_glpk/include"

    fi

    if test x"$with_glpk_libdir" != x"no"; then

      GLPK_LDFLAGS="-L$with_glpk_libdir"

    elif test x"$with_glpk" != x"yes"; then

      GLPK_LDFLAGS="-L$with_glpk/lib"

    fi

    GLPK_LIBS="-lglpk"

    lx_save_cxxflags="$CXXFLAGS"

    lx_save_ldflags="$LDFLAGS"

    lx_save_libs="$LIBS"

    CXXFLAGS="$GLPK_CFLAGS"

    LDFLAGS="$GLPK_LDFLAGS"

    LIBS="$GLPK_LIBS"

    lx_glpk_test_prog='

      extern "C" {

      #include <glpk.h>

      }

      int main(int argc, char** argv)

      {

        LPX *lp;

        lp = lpx_create_prob();

        lpx_delete_prob(lp);

        return 0;

      }'

    AC_LANG_PUSH(C++)

    AC_LINK_IFELSE([$lx_glpk_test_prog], [lx_glpk_found=yes], [lx_glpk_found=no])

    AC_LANG_POP(C++)

    CXXFLAGS="$lx_save_cxxflags"

    LDFLAGS="$lx_save_ldflags"

    LIBS="$lx_save_libs"

    if test x"$lx_glpk_found" = x"yes"; then

      AC_DEFINE([HAVE_GLPK], [1], [Define to 1 if you have GLPK.])

      AC_MSG_RESULT([yes])

    else

      GLPK_CFLAGS=""

      GLPK_LDFLAGS=""

      GLPK_LIBS=""

      AC_MSG_RESULT([no])

    fi

  fi

  GLPK_LIBS="$GLPK_LDFLAGS $GLPK_LIBS"

  AC_SUBST(GLPK_CFLAGS)

  AC_SUBST(GLPK_LIBS)

  AM_CONDITIONAL([HAVE_GLPK], [test x"$lx_glpk_found" = x"yes"])

])

AC_DEFUN([LX_CHECK_SOPLEX],

[

  AC_ARG_WITH([soplex],

AS_HELP_STRING([--with-soplex@<:@=PREFIX@:>@], [search for SOPLEX under PREFIX or under the default search paths if PREFIX is not given @<:@default@:>@])

AS_HELP_STRING([--without-soplex], [disable checking for SOPLEX]),

              [], [with_soplex=yes])

  AC_ARG_WITH([soplex-includedir],

AS_HELP_STRING([--with-soplex-includedir=DIR], [search for SOPLEX headers in DIR]),

              [], [with_soplex_includedir=no])

  AC_ARG_WITH([soplex-libdir],

AS_HELP_STRING([--with-soplex-libdir=DIR], [search for SOPLEX libraries in DIR]),

              [], [with_soplex_libdir=no])

  lx_soplex_found=no

  if test x"$with_soplex" != x"no"; then

    AC_MSG_CHECKING([for SOPLEX])

    if test x"$with_soplex_includedir" != x"no"; then

      SOPLEX_CXXFLAGS="-I$with_soplex_includedir"

    elif test x"$with_soplex" != x"yes"; then

      SOPLEX_CXXFLAGS="-I$with_soplex/include"

    fi

    if test x"$with_soplex_libdir" != x"no"; then

      SOPLEX_LDFLAGS="-L$with_soplex_libdir"

    elif test x"$with_soplex" != x"yes"; then

      SOPLEX_LDFLAGS="-L$with_soplex/lib"

    fi

    SOPLEX_LIBS="-lsoplex -lz"

    lx_save_cxxflags="$CXXFLAGS"

    lx_save_ldflags="$LDFLAGS"

    lx_save_libs="$LIBS"

    CXXFLAGS="$SOPLEX_CXXFLAGS"

    LDFLAGS="$SOPLEX_LDFLAGS"

    LIBS="$SOPLEX_LIBS"

    lx_soplex_test_prog='

      #include <soplex/soplex.h>

      int main(int argc, char** argv)

      {

        soplex::SoPlex soplex;

        return 0;

      }'

    AC_LANG_PUSH(C++)

    AC_LINK_IFELSE([$lx_soplex_test_prog], [lx_soplex_found=yes], [lx_soplex_found=no])

    AC_LANG_POP(C++)

    CXXFLAGS="$lx_save_cxxflags"

    LDFLAGS="$lx_save_ldflags"

    LIBS="$lx_save_libs"

    if test x"$lx_soplex_found" = x"yes"; then

      AC_DEFINE([HAVE_SOPLEX], [1], [Define to 1 if you have SOPLEX.])

      AC_MSG_RESULT([yes])

    else

      SOPLEX_CXXFLAGS=""

      SOPLEX_LDFLAGS=""

      SOPLEX_LIBS=""

      AC_MSG_RESULT([no])

    fi

  fi

  SOPLEX_LIBS="$SOPLEX_LDFLAGS $SOPLEX_LIBS"

  AC_SUBST(SOPLEX_CXXFLAGS)

  AC_SUBST(SOPLEX_LIBS)

  AM_CONDITIONAL([HAVE_SOPLEX], [test x"$lx_soplex_found" = x"yes"])

])