RhodeCode

Installation Instructions

=========================

Since you are reading this I assume you already obtained one of the release

tarballs and successfully extracted it. The latest version of LEMON is

available at our web page (http://lemon.cs.elte.hu/).

LEMON provides two different build environments, one is based on "autotool",

while the other is based on "cmake". This file contains instructions only for

the former one, which is the recommended build environment on Linux, Mac OSX

and other unices or if you use Cygwin on Windows. For cmake installation

instructions visit http://lemon.cs.elte.hu.

In order to install LEMON from the extracted source tarball you have to

issue the following commands:

   1. `cd lemon-x.y.z'

      This command changes to the directory which was created when you

      extracted the sources. The x.y.z part is a version number.

   2. `./configure'

      This command runs the configure shell script, which does some checks and

      creates the makefiles.

   3. `make'

      This command compiles the non-template part of LEMON into libemon.a

      file. It also compiles the programs in the tools subdirectory by

      default.

   4. `make check'

      This step is optional, but recommended. It runs the test programs that

      we developed for LEMON to check whether the library works properly on

      your platform.

   5. `make install'

      This command installs LEMON under /usr/local (you will need root

      privileges to be able to do that). If you want to install it to some

      other location, then pass the --prefix=DIRECTORY flag to configure in

      step 2. For example: `./configure --prefix=/home/username/lemon'.

   6. `make install-html'

      This command installs the documentation under share/doc/lemon/docs. The

      generated documentation is included in the tarball. If you want to

      generate it yourself, then run `make html'. Note that for this you need

      to have the following programs installed: Doxygen, Graphviz, Ghostscript,

      Latex.

Configure Options and Variables

===============================

In step 2 you can customize the actions of configure by setting variables

and passing options to it. This can be done like this:

`./configure [OPTION]... [VARIABLE=VALUE]...'

Below you will find some useful variables and options (see `./configure --help'

for more):

CXX='comp'

  Change the C++ compiler to 'comp'.

CXXFLAGS='flags'

  Pass the 'flags' to the compiler. For example CXXFLAGS='-O3 -march=pentium-m'

  turns on generation of aggressively optimized Pentium-M specific code.

--prefix=PREFIX

  Set the installation prefix to PREFIX. By default it is /usr/local.

--enable-tools

   Build the programs in the tools subdirectory (default).

--disable-tools

   Do not build the programs in the tools subdirectory.

--with-glpk[=PREFIX]

   Enable GLPK support (default). You should specify the prefix too if

   you installed GLPK to some non-standard location (e.g. your home

   directory). If it is not found, GLPK support will be disabled.

--with-glpk-includedir=DIR

   The directory where the GLPK header files are located. This is only

   useful when the GLPK headers and libraries are not under the same

   prefix (which is unlikely).

--with-glpk-libdir=DIR

   The directory where the GLPK libraries are located. This is only

   useful when the GLPK headers and libraries are not under the same

   prefix (which is unlikely).

--without-glpk

   Disable GLPK support.

--with-cplex[=PREFIX]

   Enable CPLEX support (default). You should specify the prefix too

   if you installed CPLEX to some non-standard location

   (e.g. /opt/ilog/cplex75). If it is not found, CPLEX support will be

   disabled.

--with-cplex-includedir=DIR

   The directory where the CPLEX header files are located. This is

   only useful when the CPLEX headers and libraries are not under the

   same prefix (e.g.  /usr/local/cplex/cplex75/include).

--with-cplex-libdir=DIR

   The directory where the CPLEX libraries are located. This is only

   useful when the CPLEX headers and libraries are not under the same

   prefix (e.g.

   /usr/local/cplex/cplex75/lib/i86_linux2_glibc2.2_gcc3.0/static_pic_mt).

--without-cplex

   Disable CPLEX support.

--with-soplex[=PREFIX]

   Enable SoPlex support (default). You should specify the prefix too if

   you installed SoPlex to some non-standard location (e.g. your home

   directory). If it is not found, SoPlex support will be disabled.

--with-soplex-includedir=DIR

   The directory where the SoPlex header files are located. This is only

   useful when the SoPlex headers and libraries are not under the same

   prefix (which is unlikely).

--with-soplex-libdir=DIR

   The directory where the SoPlex libraries are located. This is only

   useful when the SoPlex headers and libraries are not under the same

   prefix (which is unlikely).

--without-soplex

   Disable SoPlex support.

dnl Process this file with autoconf to produce a configure script.

dnl Version information.

m4_define([lemon_version_number],

	[m4_normalize(esyscmd([echo ${LEMON_VERSION}]))])

dnl m4_define([lemon_version_number], [])

m4_define([lemon_hg_path], [m4_normalize(esyscmd([./scripts/chg-len.py]))])

m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])

m4_define([lemon_version], [ifelse(lemon_version_number(),

			   [],

			   [lemon_hg_path().lemon_hg_revision()],

			   [lemon_version_number()])])

AC_PREREQ([2.59])

AC_INIT([LEMON], [lemon_version()], [lemon-user@lemon.cs.elte.hu], [lemon])

AC_CONFIG_AUX_DIR([build-aux])

AC_CONFIG_MACRO_DIR([m4])

AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])

AC_CONFIG_SRCDIR([lemon/list_graph.h])

AC_CONFIG_HEADERS([config.h lemon/config.h])

dnl Do compilation tests using the C++ compiler.

AC_LANG([C++])

dnl Check the existence of long long type.

AC_CHECK_TYPE(long long, [long_long_found=yes], [long_long_found=no])

if test x"$long_long_found" = x"yes"; then

  AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if you have long long.])

fi

dnl Checks for programs.

AC_PROG_CXX

AC_PROG_CXXCPP

AC_PROG_INSTALL

AC_DISABLE_SHARED

AC_PROG_LIBTOOL

AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])

AC_CHECK_PROG([gs_found],[gs],[yes],[no])

dnl Detect Intel compiler.

AC_MSG_CHECKING([whether we are using the Intel C++ compiler])

AC_COMPILE_IFELSE([#ifndef __INTEL_COMPILER

choke me

#endif], [ICC=[yes]], [ICC=[no]])

if test x"$ICC" = x"yes"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

dnl Set custom compiler flags when using g++.

if test "$GXX" = yes -a "$ICC" = no; then

  WARNINGCXXFLAGS="-Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"

fi

AC_SUBST([WARNINGCXXFLAGS])

dnl Checks for libraries.

LX_CHECK_GLPK

LX_CHECK_CPLEX

LX_CHECK_SOPLEX

AM_CONDITIONAL([HAVE_LP], [test x"$lx_lp_found" = x"yes"])

AM_CONDITIONAL([HAVE_MIP], [test x"$lx_mip_found" = x"yes"])

dnl Disable/enable building the binary tools.

AC_ARG_ENABLE([tools],

AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])

AS_HELP_STRING([--disable-tools], [do not build additional tools]),

              [], [enable_tools=yes])

AC_MSG_CHECKING([whether to build the additional tools])

if test x"$enable_tools" != x"no"; then

  AC_MSG_RESULT([yes])

else

  AC_MSG_RESULT([no])

fi

AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])

dnl Checks for header files.

AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.

AC_C_CONST

AC_C_INLINE

AC_TYPE_SIZE_T

AC_HEADER_TIME

AC_STRUCT_TM

dnl Checks for library functions.

AC_HEADER_STDC

AC_CHECK_FUNCS(gettimeofday times ctime_r)

dnl Add dependencies on files generated by configure.

AC_SUBST([CONFIG_STATUS_DEPENDENCIES],

  ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in $(top_srcdir)/cmake/version.cmake.in'])

AC_CONFIG_FILES([

Makefile

demo/Makefile

cmake/version.cmake

doc/Doxyfile

lemon/lemon.pc

])

AC_OUTPUT

echo

echo '****************************** SUMMARY ******************************'

echo

echo Package version............... : $PACKAGE-$VERSION

echo

echo C++ compiler.................. : $CXX

echo C++ compiles flags............ : $WARNINGCXXFLAGS $CXXFLAGS

echo

echo Compiler supports long long... : $long_long_found

echo

echo GLPK support.................. : $lx_glpk_found

echo CPLEX support................. : $lx_cplex_found

echo SOPLEX support................ : $lx_soplex_found

echo CLP support................... : $lx_clp_found

echo CBC support................... : $lx_cbc_found

echo

echo Build additional tools........ : $enable_tools

echo

echo The packace will be installed in

echo -n '  '

echo $prefix.

echo

echo '*********************************************************************'

echo

echo Configure complete, now type \'make\' and then \'make install\'.

echo