COIN-OR::LEMON - Graph Library

source: glemon/configure.ac @ 3:2cc5ed6e6255

Last change on this file since 3:2cc5ed6e6255 was 3:2cc5ed6e6255, checked in by Akos Ladanyi <ladanyi@…>, 11 years ago

Use hg changeset hash instead of svn revision.

File size: 2.3 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([glemon_version_major], [0])
5m4_define([glemon_version_minor], [5])
6m4_define([glemon_version_micro], [90])
7m4_define([glemon_version_nano], [])
8m4_define([glemon_version_tag], [hg_])
9m4_define([glemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
10m4_define([glemon_version], [glemon_version_major().glemon_version_minor()ifelse(glemon_version_micro(), [], [], [.glemon_version_micro()])ifelse(glemon_version_nano(), [], [], [.glemon_version_nano()])ifelse(glemon_version_tag(), [], [], glemon_version_tag(), [hg_], [[_]glemon_version_tag()[]glemon_hg_revision()], [[_]glemon_version_tag()])])
11
12AC_PREREQ([2.59])
13AC_INIT([gLEMON], [glemon_version()], [etik-ol@cs.elte.hu], [glemon])
14AC_CONFIG_AUX_DIR([build-aux])
15AC_CONFIG_MACRO_DIR([m4])
16AM_INIT_AUTOMAKE([-Wall -Werror foreign])
17AC_CONFIG_SRCDIR([main_win.h])
18AC_CONFIG_HEADERS([config.h])
19
20dnl Checks for programs.
21AC_PROG_CXX
22AC_PROG_CC
23AM_GNU_GETTEXT_VERSION([0.14.2])
24AM_GNU_GETTEXT([external])
25
26dnl Checks for libraries.
27PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0 gtkmm-2.4 >= 2.6])
28
29AC_ARG_WITH([lemon],
30AS_HELP_STRING([--with-lemon@<:@=PREFIX@:>@], [search for LEMON under PREFIX]), [], [with_lemon=no])
31if test x"$with_lemon" != x"no"; then
32  export PKG_CONFIG_PATH="$with_lemon/lib/pkgconfig/:$PKG_CONFIG_PATH"
33fi
34
35PKG_CHECK_MODULES([LEMON], [lemon >= 0.6.90])
36
37dnl Checks for header files.
38AC_CHECK_HEADERS([libintl.h locale.h])
39
40dnl Checks for typedefs, structures, and compiler characteristics.
41AC_HEADER_STDBOOL
42AC_C_CONST
43
44dnl Checks for library functions.
45AC_CHECK_FUNCS([setlocale sqrt])
46
47AC_CONFIG_FILES([
48Makefile
49glemon.spec
50autopackage/default.apspec
51po/Makefile.in
52m4/Makefile
53])
54
55AC_OUTPUT
56
57echo
58echo '****************************** SUMMARY ******************************'
59echo
60echo Package version............... : $PACKAGE-$VERSION
61echo
62echo C++ compiler.................. : $CXX
63echo C++ compiles flags............ : $CXXFLAGS
64echo
65echo LEMON CFLAGS.................. : $LEMON_CFLAGS
66echo LEMON LIBS.................... : $LEMON_LIBS
67echo
68echo The packace will be installed in
69echo -n '  '
70echo $prefix.
71echo
72echo '*********************************************************************'
73
74echo
75echo configure complete, now type \'make\' and then \'make install\'.
76echo
Note: See TracBrowser for help on using the repository browser.