COIN-OR::LEMON - Graph Library

source: glemon/configure.ac @ 5:390d05b2d25c

Last change on this file since 5:390d05b2d25c was 5:390d05b2d25c, checked in by Akos Ladanyi <ladanyi@…>, 11 years ago

Upgrade gettext infrastructure.

File size: 2.7 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([glemon_version_major], [0])
5m4_define([glemon_version_minor], [5])
6m4_define([glemon_version_micro], [90])
7m4_define([glemon_version_nano], [])
8m4_define([glemon_version_tag], [hg_])
9m4_define([glemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
10m4_define([glemon_version], [glemon_version_major().glemon_version_minor()ifelse(glemon_version_micro(), [], [], [.glemon_version_micro()])ifelse(glemon_version_nano(), [], [], [.glemon_version_nano()])ifelse(glemon_version_tag(), [], [], glemon_version_tag(), [hg_], [[_]glemon_version_tag()[]glemon_hg_revision()], [[_]glemon_version_tag()])])
11
12AC_PREREQ([2.59])
13AC_INIT([gLEMON], [glemon_version()], [etik-ol@cs.elte.hu], [glemon])
14AC_CONFIG_AUX_DIR([build-aux])
15AC_CONFIG_MACRO_DIR([m4])
16AM_INIT_AUTOMAKE([-Wall -Werror foreign])
17AC_CONFIG_SRCDIR([main_win.h])
18AC_CONFIG_HEADERS([config.h])
19
20dnl Checks for programs.
21AC_PROG_CXX
22AC_PROG_CC
23AM_GNU_GETTEXT_VERSION([0.17])
24AM_GNU_GETTEXT([external])
25
26dnl Checks for libraries.
27PKG_CHECK_MODULES([GTK], [libgnomecanvasmm-2.6 >= 2.6.0 gtkmm-2.4 >= 2.6])
28
29AC_ARG_WITH([lemon],
30AS_HELP_STRING([--with-lemon@<:@=PREFIX@:>@], [search for LEMON under PREFIX]), [], [with_lemon=no])
31if test x"$with_lemon" != x"no"; then
32  export PKG_CONFIG_PATH="$with_lemon/lib/pkgconfig/:$PKG_CONFIG_PATH"
33fi
34
35PKG_CHECK_MODULES([LEMON], [lemon >= 0.6.90], [], [AC_MSG_ERROR([
36No appropriate version of package 'lemon' found.
37
38Consider adjusting the PKG_CONFIG_PATH environment variable or using
39the --with-lemon=PREFIX configure flag if you installed it in a
40non-standard prefix.
41
42Alternatively, you may set the environment variables LEMON_CFLAGS and
43LEMON_LIBS to avoid the need to call pkg-config.  See the pkg-config
44man page for more details.])])
45
46dnl Checks for header files.
47AC_CHECK_HEADERS([libintl.h locale.h])
48
49dnl Checks for typedefs, structures, and compiler characteristics.
50AC_HEADER_STDBOOL
51AC_C_CONST
52
53dnl Checks for library functions.
54AC_CHECK_FUNCS([setlocale sqrt])
55
56AC_CONFIG_FILES([
57Makefile
58glemon.spec
59autopackage/default.apspec
60po/Makefile.in
61m4/Makefile
62])
63
64AC_OUTPUT
65
66echo
67echo '****************************** SUMMARY ******************************'
68echo
69echo Package version............... : $PACKAGE-$VERSION
70echo
71echo C++ compiler.................. : $CXX
72echo C++ compiles flags............ : $CXXFLAGS
73echo
74echo LEMON CFLAGS.................. : $LEMON_CFLAGS
75echo LEMON LIBS.................... : $LEMON_LIBS
76echo
77echo The packace will be installed in
78echo -n '  '
79echo $prefix.
80echo
81echo '*********************************************************************'
82
83echo
84echo configure complete, now type \'make\' and then \'make install\'.
85echo
Note: See TracBrowser for help on using the repository browser.