COIN-OR::LEMON - Graph Library

source: lemon-1.0/configure.ac @ 153:976a014b3797

Last change on this file since 153:976a014b3797 was 153:976a014b3797, checked in by Akos Ladanyi <ladanyi@…>, 16 years ago

Convert the EPS files to PNG when generating the documentation

File size: 4.2 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([lemon_version_major], [0])
5m4_define([lemon_version_minor], [99])
6m4_define([lemon_version_micro], [])
7m4_define([lemon_version_nano], [])
8m4_define([lemon_version_tag], [hg])
9m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
10m4_define([lemon_version], [lemon_version_major().lemon_version_minor()ifelse(lemon_version_micro(), [], [], [.lemon_version_micro()])ifelse(lemon_version_nano(), [], [], [.lemon_version_nano()])ifelse(lemon_version_tag(), [], [], lemon_version_tag(), [hg], [[_]lemon_version_tag()[_]lemon_hg_revision()], [[_]lemon_version_tag()])])
11
12AC_PREREQ([2.59])
13AC_INIT([LEMON], [lemon_version()], [lemon-devel@lemon.cs.elte.hu], [lemon])
14AC_CONFIG_AUX_DIR([build-aux])
15AC_CONFIG_MACRO_DIR([m4])
16AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])
17AC_CONFIG_SRCDIR([lemon/list_graph.h])
18AC_CONFIG_HEADERS([config.h lemon/config.h])
19
20lx_cmdline_cxxflags_set=${CXXFLAGS+set}
21
22dnl Checks for programs.
23AC_PROG_CXX
24AC_PROG_CXXCPP
25AC_PROG_INSTALL
26AC_DISABLE_SHARED
27AC_PROG_LIBTOOL
28
29AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
30AC_CHECK_PROG([gs_found],[gs],[yes],[no])
31
32if test x"$lx_cmdline_cxxflags_set" != x"set" -a "$GXX" = yes; then
33  CXXFLAGS="$CXXFLAGS -Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"
34fi
35
36dnl Checks for libraries.
37LX_CHECK_GLPK
38LX_CHECK_CPLEX
39LX_CHECK_SOPLEX
40
41dnl Disable/enable building the demo programs
42AC_ARG_ENABLE([demo],
43AS_HELP_STRING([--enable-demo], [build the demo programs])
44AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),
45              [], [enable_demo=no])
46AC_MSG_CHECKING([whether to build the demo programs])
47if test x"$enable_demo" != x"no"; then
48  AC_MSG_RESULT([yes])
49else
50  AC_MSG_RESULT([no])
51fi
52AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])
53
54dnl Disable/enable building the binary tools
55AC_ARG_ENABLE([tools],
56AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])
57AS_HELP_STRING([--disable-tools], [do not build additional tools]),
58              [], [enable_tools=yes])
59AC_MSG_CHECKING([whether to build the additional tools])
60if test x"$enable_tools" != x"no"; then
61  AC_MSG_RESULT([yes])
62else
63  AC_MSG_RESULT([no])
64fi
65AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])
66
67dnl Disable/enable building the benchmarks
68AC_ARG_ENABLE([benchmark],
69AS_HELP_STRING([--enable-benchmark], [build the benchmarks])
70AS_HELP_STRING([--disable-benchmark], [do not build the benchmarks @<:@default@:>@]),
71              [], [enable_benchmark=no])
72AC_MSG_CHECKING([whether to build the benchmarks])
73if test x"$enable_benchmark" != x"no"; then
74  AC_MSG_RESULT([yes])
75else
76  AC_MSG_RESULT([no])
77fi
78AM_CONDITIONAL([WANT_BENCHMARK], [test x"$enable_benchmark" != x"no"])
79
80dnl Checks for header files.
81AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
82
83dnl Checks for typedefs, structures, and compiler characteristics.
84AC_C_CONST
85AC_C_INLINE
86AC_TYPE_SIZE_T
87AC_HEADER_TIME
88AC_STRUCT_TM
89
90dnl Checks for library functions.
91AC_HEADER_STDC
92AC_CHECK_FUNCS(gettimeofday times ctime_r)
93
94AC_CONFIG_FILES([
95Makefile
96doc/Doxyfile
97lemon/lemon.pc
98])
99
100AC_OUTPUT
101
102echo
103echo '****************************** SUMMARY ******************************'
104echo
105echo Package version............... : $PACKAGE-$VERSION
106echo
107echo C++ compiler.................. : $CXX
108echo C++ compiles flags............ : $CXXFLAGS
109echo
110echo GLPK support.................. : $lx_glpk_found
111echo CPLEX support................. : $lx_cplex_found
112echo SOPLEX support................ : $lx_soplex_found
113echo
114echo Build benchmarks.............. : $enable_benchmark
115echo Build demo programs........... : $enable_demo
116echo Build additional tools........ : $enable_tools
117echo
118echo The packace will be installed in
119echo -n '  '
120echo $prefix.
121echo
122echo '*********************************************************************'
123
124echo
125echo Configure complete, now type \'make\' and then \'make install\'.
126echo
Note: See TracBrowser for help on using the repository browser.