COIN-OR::LEMON - Graph Library

source: lemon-1.2/configure.ac @ 567:3314f58e7b25

Last change on this file since 567:3314f58e7b25 was 567:3314f58e7b25, checked in by Balazs Dezso <deba@…>, 15 years ago

Add CBC support (#204)

File size: 4.1 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([lemon_version_number],
5        [m4_normalize(esyscmd([echo ${LEMON_VERSION}]))])
6dnl m4_define([lemon_version_number], [])
7m4_define([lemon_hg_path], [m4_normalize(esyscmd([./scripts/chg-len.py]))])
8m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
9m4_define([lemon_version], [ifelse(lemon_version_number(),
10                           [],
11                           [lemon_hg_path().lemon_hg_revision()],
12                           [lemon_version_number()])])
13
14AC_PREREQ([2.59])
15AC_INIT([LEMON], [lemon_version()], [lemon-user@lemon.cs.elte.hu], [lemon])
16AC_CONFIG_AUX_DIR([build-aux])
17AC_CONFIG_MACRO_DIR([m4])
18AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])
19AC_CONFIG_SRCDIR([lemon/list_graph.h])
20AC_CONFIG_HEADERS([config.h lemon/config.h])
21
22dnl Do compilation tests using the C++ compiler.
23AC_LANG([C++])
24
25dnl Check the existence of long long type.
26AC_CHECK_TYPE(long long, [long_long_found=yes], [long_long_found=no])
27if test x"$long_long_found" = x"yes"; then
28  AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if you have long long.])
29fi
30
31dnl Checks for programs.
32AC_PROG_CXX
33AC_PROG_CXXCPP
34AC_PROG_INSTALL
35AC_DISABLE_SHARED
36AC_PROG_LIBTOOL
37
38AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
39AC_CHECK_PROG([gs_found],[gs],[yes],[no])
40
41dnl Detect Intel compiler.
42AC_MSG_CHECKING([whether we are using the Intel C++ compiler])
43AC_COMPILE_IFELSE([#ifndef __INTEL_COMPILER
44choke me
45#endif], [ICC=[yes]], [ICC=[no]])
46if test x"$ICC" = x"yes"; then
47  AC_MSG_RESULT([yes])
48else
49  AC_MSG_RESULT([no])
50fi
51
52dnl Set custom compiler flags when using g++.
53if test "$GXX" = yes -a "$ICC" = no; then
54  WARNINGCXXFLAGS="-Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"
55fi
56AC_SUBST([WARNINGCXXFLAGS])
57
58dnl Checks for libraries.
59LX_CHECK_GLPK
60LX_CHECK_CPLEX
61LX_CHECK_SOPLEX
62LX_CHECK_CLP
63LX_CHECK_CBC
64
65AM_CONDITIONAL([HAVE_LP], [test x"$lx_lp_found" = x"yes"])
66AM_CONDITIONAL([HAVE_MIP], [test x"$lx_mip_found" = x"yes"])
67
68dnl Disable/enable building the binary tools.
69AC_ARG_ENABLE([tools],
70AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])
71AS_HELP_STRING([--disable-tools], [do not build additional tools]),
72              [], [enable_tools=yes])
73AC_MSG_CHECKING([whether to build the additional tools])
74if test x"$enable_tools" != x"no"; then
75  AC_MSG_RESULT([yes])
76else
77  AC_MSG_RESULT([no])
78fi
79AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])
80
81dnl Checks for header files.
82AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
83
84dnl Checks for typedefs, structures, and compiler characteristics.
85AC_C_CONST
86AC_C_INLINE
87AC_TYPE_SIZE_T
88AC_HEADER_TIME
89AC_STRUCT_TM
90
91dnl Checks for library functions.
92AC_HEADER_STDC
93AC_CHECK_FUNCS(gettimeofday times ctime_r)
94
95dnl Add dependencies on files generated by configure.
96AC_SUBST([CONFIG_STATUS_DEPENDENCIES],
97  ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in $(top_srcdir)/cmake/version.cmake.in'])
98
99AC_CONFIG_FILES([
100Makefile
101demo/Makefile
102cmake/version.cmake
103doc/Doxyfile
104lemon/lemon.pc
105])
106
107AC_OUTPUT
108
109echo
110echo '****************************** SUMMARY ******************************'
111echo
112echo Package version............... : $PACKAGE-$VERSION
113echo
114echo C++ compiler.................. : $CXX
115echo C++ compiles flags............ : $WARNINGCXXFLAGS $CXXFLAGS
116echo
117echo Compiler supports long long... : $long_long_found
118echo
119echo GLPK support.................. : $lx_glpk_found
120echo CPLEX support................. : $lx_cplex_found
121echo SOPLEX support................ : $lx_soplex_found
122echo CLP support................... : $lx_clp_found
123echo CBC support................... : $lx_cbc_found
124echo
125echo Build additional tools........ : $enable_tools
126echo
127echo The packace will be installed in
128echo -n '  '
129echo $prefix.
130echo
131echo '*********************************************************************'
132
133echo
134echo Configure complete, now type \'make\' and then \'make install\'.
135echo
Note: See TracBrowser for help on using the repository browser.