COIN-OR::LEMON - Graph Library

source: lemon-1.2/configure.ac @ 607:9ad8d2122b50

Last change on this file since 607:9ad8d2122b50 was 517:2b6d5d22bb23, checked in by Alpar Juttner <alpar@…>, 15 years ago

Merge

File size: 4.5 KB
Line 
1dnl Process this file with autoconf to produce a configure script.
2
3dnl Version information.
4m4_define([lemon_version_number],
5        [m4_normalize(esyscmd([echo ${LEMON_VERSION}]))])
6dnl m4_define([lemon_version_number], [])
7m4_define([lemon_hg_path], [m4_normalize(esyscmd([./scripts/chg-len.py]))])
8m4_define([lemon_hg_revision], [m4_normalize(esyscmd([hg id -i]))])
9m4_define([lemon_version], [ifelse(lemon_version_number(),
10                           [],
11                           [lemon_hg_path().lemon_hg_revision()],
12                           [lemon_version_number()])])
13
14AC_PREREQ([2.59])
15AC_INIT([LEMON], [lemon_version()], [lemon-user@lemon.cs.elte.hu], [lemon])
16AC_CONFIG_AUX_DIR([build-aux])
17AC_CONFIG_MACRO_DIR([m4])
18AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects nostdinc])
19AC_CONFIG_SRCDIR([lemon/list_graph.h])
20AC_CONFIG_HEADERS([config.h lemon/config.h])
21
22dnl Do compilation tests using the C++ compiler.
23AC_LANG([C++])
24
25dnl Check the existence of long long type.
26AC_CHECK_TYPE(long long, [long_long_found=yes], [long_long_found=no])
27if test x"$long_long_found" = x"yes"; then
28  AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if you have long long.])
29fi
30
31dnl Checks for programs.
32AC_PROG_CXX
33AC_PROG_CXXCPP
34AC_PROG_INSTALL
35AC_DISABLE_SHARED
36AC_PROG_LIBTOOL
37
38AC_CHECK_PROG([doxygen_found],[doxygen],[yes],[no])
39AC_CHECK_PROG([gs_found],[gs],[yes],[no])
40
41dnl Detect Intel compiler.
42AC_MSG_CHECKING([whether we are using the Intel C++ compiler])
43AC_COMPILE_IFELSE([#ifndef __INTEL_COMPILER
44choke me
45#endif], [ICC=[yes]], [ICC=[no]])
46if test x"$ICC" = x"yes"; then
47  AC_MSG_RESULT([yes])
48else
49  AC_MSG_RESULT([no])
50fi
51
52dnl Set custom compiler flags when using g++.
53if test "$GXX" = yes -a "$ICC" = no; then
54  WARNINGCXXFLAGS="-Wall -W -Wall -W -Wunused -Wformat=2 -Wctor-dtor-privacy -Wnon-virtual-dtor -Wno-char-subscripts -Wwrite-strings -Wno-char-subscripts -Wreturn-type -Wcast-qual -Wcast-align -Wsign-promo -Woverloaded-virtual -ansi -fno-strict-aliasing -Wold-style-cast -Wno-unknown-pragmas"
55fi
56AC_SUBST([WARNINGCXXFLAGS])
57
58dnl Checks for libraries.
59LX_CHECK_GLPK
60LX_CHECK_CPLEX
61LX_CHECK_SOPLEX
62LX_CHECK_CLP
63
64AM_CONDITIONAL([HAVE_LP], [test x"$lx_lp_found" = x"yes"])
65AM_CONDITIONAL([HAVE_MIP], [test x"$lx_mip_found" = x"yes"])
66
67dnl Disable/enable building the demo programs.
68AC_ARG_ENABLE([demo],
69AS_HELP_STRING([--enable-demo], [build the demo programs])
70AS_HELP_STRING([--disable-demo], [do not build the demo programs @<:@default@:>@]),
71              [], [enable_demo=no])
72AC_MSG_CHECKING([whether to build the demo programs])
73if test x"$enable_demo" != x"no"; then
74  AC_MSG_RESULT([yes])
75else
76  AC_MSG_RESULT([no])
77fi
78AM_CONDITIONAL([WANT_DEMO], [test x"$enable_demo" != x"no"])
79
80dnl Disable/enable building the binary tools.
81AC_ARG_ENABLE([tools],
82AS_HELP_STRING([--enable-tools], [build additional tools @<:@default@:>@])
83AS_HELP_STRING([--disable-tools], [do not build additional tools]),
84              [], [enable_tools=yes])
85AC_MSG_CHECKING([whether to build the additional tools])
86if test x"$enable_tools" != x"no"; then
87  AC_MSG_RESULT([yes])
88else
89  AC_MSG_RESULT([no])
90fi
91AM_CONDITIONAL([WANT_TOOLS], [test x"$enable_tools" != x"no"])
92
93dnl Checks for header files.
94AC_CHECK_HEADERS(limits.h sys/time.h sys/times.h unistd.h)
95
96dnl Checks for typedefs, structures, and compiler characteristics.
97AC_C_CONST
98AC_C_INLINE
99AC_TYPE_SIZE_T
100AC_HEADER_TIME
101AC_STRUCT_TM
102
103dnl Checks for library functions.
104AC_HEADER_STDC
105AC_CHECK_FUNCS(gettimeofday times ctime_r)
106
107dnl Add dependencies on files generated by configure.
108AC_SUBST([CONFIG_STATUS_DEPENDENCIES],
109  ['$(top_srcdir)/doc/Doxyfile.in $(top_srcdir)/lemon/lemon.pc.in $(top_srcdir)/cmake/version.cmake.in'])
110
111AC_CONFIG_FILES([
112Makefile
113cmake/version.cmake
114doc/Doxyfile
115lemon/lemon.pc
116])
117
118AC_OUTPUT
119
120echo
121echo '****************************** SUMMARY ******************************'
122echo
123echo Package version............... : $PACKAGE-$VERSION
124echo
125echo C++ compiler.................. : $CXX
126echo C++ compiles flags............ : $WARNINGCXXFLAGS $CXXFLAGS
127echo
128echo Compiler supports long long... : $long_long_found
129echo
130echo GLPK support.................. : $lx_glpk_found
131echo CPLEX support................. : $lx_cplex_found
132echo SOPLEX support................ : $lx_soplex_found
133echo CLP support................... : $lx_clp_found
134echo
135echo Build demo programs........... : $enable_demo
136echo Build additional tools........ : $enable_tools
137echo
138echo The packace will be installed in
139echo -n '  '
140echo $prefix.
141echo
142echo '*********************************************************************'
143
144echo
145echo Configure complete, now type \'make\' and then \'make install\'.
146echo
Note: See TracBrowser for help on using the repository browser.